Array reference problem

hda has asked for the wisdom of the Perl Monks concerning the following question:

Dear monks,

I am working with a program in which some arrays must be accessed based on their names. I am experiencing a weird problem since some arrays can be accessed and others not.

The example below should give an impression of how the problem goes. I have some arrays defined on some data and named as "@descriptor_array_(some number)". Then I have other arrays, named as "@array_dummy_(some number)" which I construct with data read from files and some number crunching. The thing is that I must access these arrays recursively based on their names, and for doing that I use a reference of the type:

$name = sprintf "%s%s",'descriptor_array',$array_no;
print @$name;
[download]

Well, the problem is that the predefined arrays cannot be accessed whereas the others can. Both types are defined using "my" within the main loop of the program, and the loop where I call these arrays has the instruction "no strict 'refs'"

Any thoughts???

UPDATE: $array_no is just an example, in my program the refernce is a string that I compose with sprintf.

my @descriptor_array1 = ( 1, 2, 3, 4 );
my @descriptor_array2 = ( 1, 2, 3, 4 );
my @descriptor_array3 = ( 1, 2, 3, 4 );
my @descriptor_array4 = ( 1, 2, 3, 4 );
..........................

my (@array_dummy1,@array_dummy2,@array_dummy3);

foreach my $array_no(@insomearray) {

no strict 'refs';

$name = sprintf "%s%s",'descriptor_array',$array_no;
print @$name;   # prints nothing!

$name = sprintf "%s%s",'array_dummy',$array_no;
print @$name;   # prints "array_dummy!

}
[download]

Comment on Array reference problem Select or Download Code

Replies are listed 'Best First'.
Re: Array reference problem by davorg (Chancellor) on Jul 07, 2009 at 16:16 UTC
I am working with a program in which some arrays must be accessed based on their names. You really don't want to do that. No, I mean you really don't want to do that. `use strict` makes symbolic references illegal for a reason. There are a tiny number of advanced techniques where you need to use symbolic references. This isn't one of them. In this case, what you really want is a hash. `#!/usr/bin/perl use strict; use warnings; my %descriptor_array = ( 1 => [ 1, 2, 3, 4 ], 2 => [ 1, 2, 3, 4 ], 3 => [ 1, 2, 3, 4 ], 4 => [ 1, 2, 3, 4 ], ); foreach my $array_no (1 .. 4) { print "$array_no: @{$descriptor_array{$array_no}}\n"; }` [download] If you alter your code to use a model like this then you'll be far happier. perldsc will probably be useful to you. -- See the Copyright notice on my home node. Perl training courses	[reply] [d/l]
Re: Array reference problem by ikegami (Patriarch) on Jul 07, 2009 at 16:17 UTC
Why it's stupid to 'use a variable as a variable name' `my @descriptor_array = ( [ 1, 2, 3, 4 ], [ 2, 3, 4, 5 ], [ 3, 4, 5, 6 ], [ 4, 5, 6, 7 ], ); my @insomearray = (0, 3); for my $array_no (@insomearray) { my $array = $descriptor_array[$array_no]; print("$array_no $array @$array\n"); }` [download] `0 ARRAY(0x814ec28) 1 2 3 4 3 ARRAY(0x814f8e8) 4 5 6 7` [download]	[reply] [d/l] [select]
Re: Array reference problem by JavaFan (Canon) on Jul 07, 2009 at 16:04 UTC
`$name = sprintf "%s%s",'descriptor_array',$array_no; print @$name;` [download] Since `$name` contains a string, `@$name` will access a package variable - not a lexical variable introduced with `my`. Either use `our`, or use a hash (or array) of arrays, instead of using the names directly.	[reply] [d/l] [select]
Re^2: Array reference problem by hda (Chaplain) on Jul 07, 2009 at 16:14 UTC
Thanks, that worked. However, I can't understand why one of these two 'families' of arrays can be accessed whereas the other not.	[reply]
Re^3: Array reference problem by JavaFan (Canon) on Jul 07, 2009 at 19:36 UTC
Because only for package variables does the lookup happen at runtime.	[reply]
Re: Array reference problem by SuicideJunkie (Vicar) on Jul 07, 2009 at 16:19 UTC
Why exactly are you not using an array of arrays or a hash of arrays? Strict frowns on the use of such refs for a good reason. Hash of Arrays example: `my $HoA; $HoA->{CountArray} = [1, 2, 3, 4]; my @AlphaArray = ('a', 'b', 'c', 'd'); $HoA->{AlphaArray} = \@AlphaArray; DoStuff($HoA, 'AlphaArray'); sub DoStuff { my $HoA = shift; my $desiredArrayName = shift; die "There is no such thing as '$desiredArrayName'" unless exists ($ +HoA->{$desiredArrayName}); foreach my $value (@{$HoA->{$desiredArrayName}}) { print "$value\n"; } }` [download]	[reply] [d/l]


Think about Loose Coupling
	PerlMonks