http://qs1969.pair.com?node_id=778397

brycen has asked for the wisdom of the Perl Monks concerning the following question:

This code works great in perl 5.10.0, but does not run in 5.8.8. Is there a Monk who can advise how to achieve the same effect using the older Perl? The 5.8.8 in question has ithreads, not 5005threads (specifying use Thread gives ithreads):

The end goal is code that alerts if a thread (which will run some blocking I/O) runs too slowly or too long. 

#!/usr/bin/perl
use strict;
use warnings;
use threads;

my $thread1 = threads::async  {
    my $sleep = int(rand() * 5);
    print("Thread sleeping $sleep seconds\n");
    sleep($sleep);
    return($sleep);
};
sleep(2);
if( $thread1->is_running() ) {
   print("Alert!  That thread took more than 2 seconds!\n");
} else {
   print("No problem\n");
}
print "Thread eventually returned ".$thread1->join()."\n";

[download]
This is a reformulated version of 777702

Replies are listed 'Best First'.
Re: $thread->is_running() in perl 5.8.8 - catching slow threads
by ikegami (Patriarch) on Jul 08, 2009 at 20:23 UTC

    is_running() is not implemented in Perl 5.8.8. And I can't upgrade to 5.10

    threads is dual-lifed. You can upgrade the module without upgrading Perl.

    (Quoted text from linked thread.)

[reply]
[d/l]
Re: $thread->is_running() in perl 5.8.8 - catching slow threads
by BrowserUk (Patriarch) on Jul 08, 2009 at 21:03 UTC

    If you can't upgrade to a recent version of threads (why?), then you can achieve something similar with a shared variable (or hash as shown here if you will have multiple threads): 

    #!/usr/bin/perl
use strict;
use warnings;
use threads;
use threads::shared;
use Data::Dumper;


my %running :shared;

my $thread1 = threads::async  {
    {
        lock %running;
        $running{ threads->tid } = 1;
    }
    my $sleep = int(rand() * 5);

    printf "thread: %d sleeping for %d seconds\n", threads->tid, $slee
+p;
    sleep($sleep);
    printf "thread: %d Awakes\n", threads->tid;

    lock %running;
    delete $running{ threads->tid };
    printf "thread: %d about to return\n", threads->tid;
    return($sleep);
};

print "Main sleeping for 2\n";
sleep(3);
print "Main awakes\n";

if( exists $running{ $thread1->tid } ) {
    print 'email("alert")' . "\n";
} else {
   print "Thread finished in time, no problem\n";
}

print "Thread eventually returned ".$thread1->join()."\n";
print "Exit\n";

__END__
C:\test>junk
Main sleeping for 2
thread: 1 sleeping for 2 seconds
thread: 1 Awakes
thread: 1 about to return
Main awakes
Thread finished in time, no problem
Thread eventually returned 2
Exit

C:\test>junk
Main sleeping for 2
thread: 1 sleeping for 0 seconds
thread: 1 Awakes
thread: 1 about to return
Main awakes
Thread finished in time, no problem
Thread eventually returned 0
Exit

C:\test>junk
Main sleeping for 2
thread: 1 sleeping for 3 seconds
Main awakes
thread: 1 Awakes
email("alert")
thread: 1 about to return
Thread eventually returned 3
Exit

    [download]
    Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.
    "Science is about questioning the status quo. Questioning authority".
    In the absence of evidence, opinion is indistinguishable from prejudice.
[reply]
[d/l]

Back to Seekers of Perl Wisdom