#!/usr/bin/perl -w

use strict;


# Generate a closure that implements a Feedback Shift Register:
# Usage:
#    my $fsr= genFSR( $bits, $seed, \&feedBack, [@taps] );
#    my $nextBit= $fsr->();

sub genFSR {
    my( $bits, $seed, $code, $avTaps )= @_;
    return sub {
        my $ret= $seed & 1;
        my $b= $code->(  map $seed & 1<<$_ ? 1 : 0, @$avTaps  );
        $seed >>= 1;
        $seed |= (1&$b)<<$bits;
        return $ret;
    };
}


# XOR all arguments:
sub xorList {
    my $b= 0;
    $b ^= pop   while @_;
    return $b;
}


# Generate a Linear Feedback Shift Register closure:
# Usage:
#    my $lfsr= genFSR( $bits, $seed, [@taps] );
#    $nextBit= $lfsr->();

sub genLFSR {
    my( $bits, $seed, $avTaps )= @_;
    return genFSR( $bits, $seed, \&xorList, $avTaps );
}


# Test the above using command-line arguments:
# Usage:  lfsr nBits Seed tap tap [tap [...]]
#    perl lfsr.pl 5 10 3 5
#    perl lfsr.pl 5 0b1010 3 5  # Same if using perl 5.6 or later
# Both of the above use:
#    genLFSR( 5, 10, [3,5] );

my $bits= shift;
my $seed= shift;
$seed= oct($seed)   if  $seed =~ /^0/;
my $lfsr= genLFSR( $bits, $seed, [@ARGV] );
while( 1 ) {
    print join( " ", map $lfsr->(), 1..$bits ), $/;
}