No real Perl code here, but I thought it would be neat to try to port the map() and grep() functions to AppleScript and see if that much-maligned language could use a little higher-order programming love.
I've also posted a thread on MacScripter, but here's the code in question. Thoughts?
on map over theList given script:theScript
set resultList to {}
repeat with theItem in theList
set resultList to resultList & theScript's lambda(theItem)
end repeat
return resultList
end map
on grep over theList given script:theScript
set resultList to {}
repeat with theItem in theList
tell theScript
if lambda(theItem) is true then
set resultList to resultList & theItem
end if
end tell
end repeat
return resultList
end grep
-- end library
script mapScript
property HowMany : 0
on lambda(someone)
set HowMany to HowMany + 1
return someone & " Gardner " & HowMany
end lambda
end script
map over {"Mark", "Erin", "David"} given script:mapScript
script grepScript
on lambda(someone)
considering case
if contents of someone is equal to "David" then
return true
end if
return false
end considering
end lambda
end script
grep over {"Mark", "Erin", "David"} given script:grepScript
