sub list2range {
  local $_ = join ',' => @_;
  s/(\w+)(?:,((??{''.++(my$x=$+)})))+/$1-$+/g;
  return $_;
}
[download]

#!/usr/bin/perl -w
use strict;

sub human
{
    my (@r, $g, $s, $l);
    while (@_) {
        $l = $g = $s = shift;
        $l = shift while (++$g eq ($_[0] || ''));
        push(@r, $s eq $l ? $s : "$s-$l");
    }
    @r;
}

print join(", ", human(1..12, 14..21, 'aa'..'af', 'zz'..'aaf')), "\n";
print join(", ", human(1, 2, 3, 5, 7, 8, 9, 11, 14)), "\n";
[download]

Output is:

1-12, 14-21, aa-af, zz-aaf
1-3, 5, 7-9, 11, 14
[download]

update: made work with solo items (thanks CharlesClarkson!)

That's not working for the original list: print join(", ", human(1, 2, 3, 5, 7, 8, 9, 11, 14)), "\n"; prints:1-3, 5-3, 7-9, 11-9, 14-9

After some thought, I'd like to modify the if to this:

if (($array[$x] + 1 == $array[$x+1]) &&
($array[$x] + 2 == $array[$x+2])) {
[download]

That way you don't end up with display-length sub-lists like "1-2, 4-5" in lists. Again, I'm sure there's a better way, but...

sub human {
        my %h;
        @h{@_}=@_;
        $_=join(',',map { $h{$_}?$_:"*" } $_[0]..$_[-1]);
        s/(\w+),(\w+,)*(\w+)/$1-$3/g;
        s/,(\*,)+/,/g;
        split(",");
}
[download]

Perhaps I have too much time on my hands. This sub allows you to change the separators and handles mixed letters and numbers, 0 and negative numbers. Can be called in scalar or list context.

#!/usr/bin/perl

use strict;
use warnings;

sub human {
    # range separator defaults to '-'
    my $range_separator = '-';

    # last item separator defaults ''
    my $last_item_separator = '';

    # list separator for scalar context
    my $list_separator = ', ';

    if (ref $_[0] eq 'ARRAY') {
        my $format = shift;
        $range_separator = $$format[0] if $$format[0];
        $last_item_separator = $$format[1] if $$format[1];
        $list_separator = $$format[2] if $$format[2];
    }

    # get list;
    my @array = @_;

    # load first range
    my @range = ($array[0], $array[0]);
    shift @array;

    # the human readable array
    my @human;

    # last item is a dummy, should be less than $array[-1]
    foreach my $to (@array, $range[0]) {

        # use autoincrement to get next item
        my $next = $range[1];
        $next++;

        if ($next eq $to) {
            # increase range
            $range[1]++;
            next;
        }
        # use autoincrement to get next item (for testing below)
        $next = $range[0];
        $next++;

        # add current range to human readable array
        push @human,
            $range[1] eq $range[0]  ?  $range[0] :
            $range[1] eq $next      ?  @range    :
                                      "$range[0]$range_separator$range
+[1]";

        # load next range
        @range = ($to, $to);
    }
    unless ($last_item_separator eq '') {
        my $last_item = pop @human;
        push @human, "$last_item_separator$last_item";
    }

    return wantarray ? @human : join $list_separator, @human;
}

my @array = (1, 2, 3, 5, 7, 8, 9, 11, 14);
print 'Read chapters: ', scalar human(@array), " before friday.\n";
print "Read these chapters by friday:\n", scalar human([' through ', '
+and ', "\n"], @array), "\n\n";
print 'Read pages: ', (join ', ', human(@array)), ".\n\n";
print join(', ', human(0, 2 .. 4, 6, 7, 9, 11 .. 14, 17 .. 19)), "\n";
print join(', ', human(1 .. 19)), "\n";
print scalar human(1 .. 19), "\n\n";
print "Mixed:\n";
@array = (0, 2 .. 4, 6, 7, 9, 'A' .. 'F', 11 .. 14, 'G', 17 .. 20);
print join(', ', human([' to '], @array)), "\n";
print scalar human(['-', '& '], @array), "\n\n";

print join(', ', human('aa' .. 'ba', -100 .. 4)), "\n";
print scalar human([' - ', undef, ' and '], 'aa' .. 'ba', '-100' .. 4)
+, "\n\n";

__END__
[download]

Read chapters: 1-3, 5, 7-9, 11, 14 before friday.
Read these chapters by friday:
1 through 3
5
7 through 9
11
and 14

Read pages: 1-3, 5, 7-9, 11, 14.

0, 2-4, 6, 7, 9, 11-14, 17-19
1-19
1-19

Mixed:
0, 2 to 4, 6, 7, 9, A to F, 11 to 14, G, 17 to 20
0, 2-4, 6, 7, 9, A-F, 11-14, G, & 17-20

aa-ba, -100-4
aa - ba and -100 - 4
[download]

Yep, way too much time