There is alot of code around for doing this, here are a few methods to save you the search. They all involve running a loop of some kind. In the Glib examples, you can substitute another event loop of your choosing.
Term-ReadKey in a thread
#!/usr/bin/perl
use warnings;
use strict;
use Term::ReadKey;
use threads;
$|++;
ReadMode('cbreak');
# works non-blocking if read stdin is in a thread
my $count = 0;
my $thr = threads->new(\&read_in)->detach;
while(1){
print "test\n";
sleep 1;
}
ReadMode('normal'); # restore normal tty settings
sub read_in{
while(1){
my $char;
if (defined ($char = ReadKey(0)) ) {
print "\t\t$char->", ord($char),"\n";
#process key presses here
if($char eq 'q'){exit}
#if(length $char){exit} # panic button on any key :-)
}
}
}
__END__
And an event loop based example using Glib
#!/usr/bin/perl
use warnings;
use strict;
use Glib;
my $main_loop = Glib::MainLoop->new;
Glib::IO->add_watch (fileno 'STDIN', [qw/in/], \&watch_callback, 'STDI
+N');
#just to show it's non blocking
my $timer1 = Glib::Timeout->add (1000, \&testcallback, undef, 1 );
$main_loop->run;
sub watch_callback {
# print "@_\n";
my ($fd, $condition, $fh) = @_;
my $line = readline STDIN;
print $line;
#always return TRUE to continue the callback
return 1;
}
sub testcallback{
print "\t\t\t".time."\n";
}
__END__
Another one combining an eventloop Glib with threads
#!/usr/bin/perl
use warnings;
use strict;
use Glib;
use Term::ReadKey;
use threads;
$|++;
ReadMode('cbreak');
# works non-blocking if read stdin is in a thread
my $count = 0;
my $thr = threads->new(\&read_in)->detach;
my $main_loop = Glib::MainLoop->new;
my $timer = Glib::Timeout->add (1000, \&timer_callback, undef, 1 );
# can also have filehandle watches
#my $watcher;
#$watcher = Glib::IO->add_watch( fileno( $pty ), ['in', 'hup'], \&call
+back);
# must be done after main_loop is running
#Glib::Idle->add( sub{});
#print "$ps\n";
my $timer1 = Glib::Timeout->add (10, \&testcallback, undef, 1 );
$main_loop->run;
ReadMode('normal'); # restore normal tty settings
sub testcallback{
my $ps = `ps auxww`;
print "$ps\n";
return 0; #only run once
}
sub timer_callback{
#do stuff
$count++;
print "\n$count\n";
return 1;
}
sub read_in{
while(1){
my $char;
if (defined ($char = ReadKey(0)) ) {
print "\t\t$char->", ord($char),"\n";
#process key presses here
if($char eq 'q'){exit}
#if(length $char){exit} # panic button on any key :-)
if($char eq 'p'){
Glib::Idle->add(
sub{
my $ps = `ps auxww`;
print "$ps\n";
return 0; # run only once
} );
}
}
}
}
__END__
And finally an IO::Select based solution to avoid threads
#!/usr/bin/perl
use warnings;
use strict;
use IO::Select;
# remember what select says about mixing
# buffered reading and "select", so even though the
# code works, you might want to substitute
# the read via <$fh> with:
# my $input;
# sysread( $fh, $input, 1024);
# loop every 5 second
my $timeout = 5;
my $s = IO::Select->new();
$s->add( \*STDIN );
while (1) {
if ( my @ready = $s->can_read($timeout) ) {
# we got input
for my $fh (@ready) {
print "$fh\n";
my $input = <$fh>;
print "got: $input";
}
}
else {
# no input
}
# just to show that we're looping
print scalar localtime,"\n";
}
