Re: Using Number Ranges in a Dispatch Table

The map trap. Run this:

#!/usr/bin/perl

use strict;
use warnings;
use Data::Dumper;

my %oops=(
    A => 1,
    map { $_ => 2 } ('B','C'),
    map { $_ => 3 } ('D','E'),
    F => 4,
);

print Dumper(\%oops);
[download]

Look at the output. Then add ( ) around each map expression:

#!/usr/bin/perl

use strict;
use warnings;
use Data::Dumper;

my %oops=(
    A => 1,
    (map { $_ => 2 } ('B','C')),
    (map { $_ => 3 } ('D','E')),
    F => 4,
);

print Dumper(\%oops);
[download]

Alexander

--
Today I will gladly share my knowledge and experience, for there are no sweeter words than "I told you so". ;-)

Comment on Re: Using Number Ranges in a Dispatch Table Select or Download Code

Replies are listed 'Best First'.
Re^2: Using Number Ranges in a Dispatch Table by planetscape (Chancellor) on Feb 18, 2012 at 19:32 UTC
Bless you! I thought the technique itself should be sound, and the solution something simple, but I didn't realize it would be this simple! Thanks! HTH, planetscape	[reply]
Re^3: Using Number Ranges in a Dispatch Table by Anonymous Monk on Feb 18, 2012 at 19:36 UTC
No need to double up on the parentheses `(map { $_ => 2 } 'B','C'), (map { $_ => 3 } 'D','E'),` [download]	[reply] [d/l]
Re^4: Using Number Ranges in a Dispatch Table by ForgotPasswordAgain (Priest) on Feb 19, 2012 at 01:27 UTC
If we're being nitpicky :) no need to create a lexical block for map: `$ perl -Mstrict -MData::Dumper -we'my%h=( (map +($_=>2), "B","C","D"), + one=>1 ); print Dumper(\%h)' $VAR1 = { 'one' => 1, 'D' => 2, 'C' => 2, 'B' => 2 };` [download]	[reply] [d/l]
Re^2: Using Number Ranges in a Dispatch Table by oko1 (Deacon) on Feb 19, 2012 at 17:06 UTC
But isn't this always the case when you're dealing with statements that take lists as arguments? `# Ooops! print join ",", @foo, "\n"; # Ooops! print grep /o/, @foo, "Hello world!\n"; # Ooops! print table{ map { tr(td($_->[0]), td($_->[1])) } @foo, ...` [download] My rule of thumb is, if one of these statements is followed by anything besides its argument, then parenthesize that statement's entire argument list. `# De-oopsed. print join(",", @foo), "\n"; print grep(/o/, @foo), "Hello world!\n"; print table{ map({ tr(td($_->[0]), td($_->[1])) } @foo), ...` [download] -- I hate storms, but calms undermine my spirits. -- Bernard Moitessier, "The Long Way"	[reply] [d/l] [select]


No such thing as a small change
	PerlMonks