Bizarro %+ hash slice bug in Perl 5.10 to 5.14.

tobyink has asked for the wisdom of the Perl Monks concerning the following question:

The following code fails in Perl 5.10 to 5.14, but passes in 5.16.

use 5.010;
use strict;
use Test::More tests => 2;

my $string = 'foo bar';
my $regexp = qr{^ (?<word1>\w+) \W+ (?<word2>\w+) $}x;

sub get_words_1
{
    if ($string =~ $regexp)
    {
        my @tmp = @+{qw/ word1 word2 /};
        return @tmp;
    }
    return;
}

sub get_words_2
{
    if ($string =~ $regexp)
    {
        return @+{qw/ word1 word2 /};
    }
    return;
}

my @expected = qw(foo bar);

my @results1 = get_words_1();
my @results2 = get_words_2();

is_deeply(\@results1, \@expected);
is_deeply(\@results2, \@expected);
[download]

Is this apparent bug and bugfix documented anywhere? I can't find any reference to it in perl5160delta.

perl -E'sub Monkey::do{say$_,for@_,do{($monkey=[caller(0)]->[3])=~s{::}{ }and$monkey}}"Monkey say"->Monkey::do'

Comment on Bizarro %+ hash slice bug in Perl 5.10 to 5.14. Download Code

Replies are listed 'Best First'.
Re: Bizarro %+ hash slice bug in Perl 5.10 to 5.14. by Anonymous Monk on Jun 17, 2012 at 09:23 UTC
I investigate :) Read more... (1018 Bytes) I don't think this is documented anywhere, and I suspect it hasn't been discovered and fixed intentionally -- you should submit (perlbug) the test case for inclusion into http://perl5.git.perl.org/perl.git/blob/HEAD:/ext/Tie-Hash-NamedCapture/t/tiehash.t update: Forgot to search for %+, I found #105024: UNIVERSAL::AUTOLOAD breaks named captures/%-/%+, which could be responsible for fixing this, but Devel::Trace doesn't show any autoload / UNIVERSAL::AUTOLOAD	[reply]
Re^2: Bizarro %+ hash slice bug in Perl 5.10 to 5.14. by tobyink (Canon) on Jun 17, 2012 at 09:55 UTC
Thanks for looking into it. I had seen the UNIVERSAL::AUTOLOAD bug (it's the only mention of `%+` in perl516delta), but dismissed it as I don't think Test::More installs a UNIVERSAL::AUTOLOAD, and I certainly wasn't. But you're right that the bug I was seeing could have been inadvertently fixed at the same time. I'll submit the test case to p5p in a couple of days unless anyone can convince me in this thread that the problem is already known to the core devs and tested for somewhere. This bug has already bitten one of my CPAN releases. Hurray to CPAN testers for alerting me to it so quickly! `perl -E'sub Monkey::do{say$_,for@_,do{($monkey=[caller(0)]->[3])=~s{::}{ }and$monkey}}"Monkey say"->Monkey::do'`	[reply] [d/l]
Re: Bizarro %+ hash slice bug in Perl 5.10 to 5.14. by dave_the_m (Monsignor) on Jun 17, 2012 at 16:58 UTC
It was fixed by the following commit, which is a more general fix than just %+: commit 6f48390ab209d16ee8f795f0a83677c8bd9ac69c Author: Father Chrysostomos <sprout@cpan.org> Date: Wed Jan 4 23:28:54 2012 -0800 [perl #95548] Returned magical temps are not copied return and leavesub, for speed, were not copying temp variables wi +th a refcount of 1, which is fine as long as the fact that it was not c +op- ied is not observable. With magical variables, that can be observed, so we have to fore +go the optimisation and copy the variable if it’s magical. This obviously applies only to rvalue subs. [download] Dave.	[reply] [d/l]
Re^2: Bizarro %+ hash slice bug in Perl 5.10 to 5.14. by tobyink (Canon) on Jun 17, 2012 at 18:30 UTC
Ah, this looks like it! The diff can be found here. The commit included a couple of tests, but I'll send p5p my test file too, just in case they want it. `perl -E'sub Monkey::do{say$_,for@_,do{($monkey=[caller(0)]->[3])=~s{::}{ }and$monkey}}"Monkey say"->Monkey::do'`	[reply]


Come for the quick hacks, stay for the epiphanies.
	PerlMonks