You can get pretty much the same techniques out of Haskell, but you'll miss currying.

Huh? Haskell's curried...

foo a b c = a ++ c ++ b
with_parens a b = foo a b
y = with_parens "<" ">"
[download]

then print (y "banana") prints "<banana>". BTW, if you haven't, you should definitely check out Haskell, as it can be a truly mind-bending experience. It's easy to get up and running with the HUGS interpreter, now with delicious readline support.

/s

Update: you won't miss the currying anymore...

use strict;
use Carp;
use Attribute::Handlers;

sub _curry {
    my ($n, $func, @args) = @_;
    return sub {
    my $narg = @args + @_;    
    if ($narg > $n) {
        carp "$narg args to curried function (expects $n).";
    } elsif ($narg < $n) {
        return _curry($n, $func, @args, @_);
    } else {
        return &$func(@args, @_);
    }
    };
}

sub curry : ATTR(CODE) {
    my ($package, $symbol, $code, $name, $n) = @_;
    confess "Usage: sub mysub : curry(N), where N > 0"
    unless $n;
    local($^W) = 0;
    no strict 'refs';
    my $newsub = _curry($n, $code);
    *{$package . '::' . *{$symbol}{NAME}} = $newsub;
}

sub foo :curry(3) {
    print "foo: @_\n";
}

my $x = foo(1,2);
&$x(3);
&$x(2);
[download]

---

---

• Are you posting in the right place? Check out Where do I post X? to know for sure.
• Posts may use any of the Perl Monks Approved HTML tags. Currently these include the following:

  <code> <a> <b> <big> <blockquote> <br /> <dd> <dl> <dt> <em> <font> <h1> <h2> <h3> <h4> <h5> <h6> <hr /> <i> <li> <nbsp> <ol> <p> <small> <strike> <strong> <sub> <sup> <table> <td> <th> <tr> <tt> <u> <ul>

• Snippets of code should be wrapped in <code> tags not <pre> tags. In fact, <pre> tags should generally be avoided. If they must be used, extreme care should be taken to ensure that their contents do not have long lines (<70 chars), in order to prevent horizontal scrolling (and possible janitor intervention).
• Want more info? How to link or How to display code and escape characters are good places to start.