#!/usr/bin/perl -w
use strict;

chomp(my @lines = <DATA>);
my %results;

for my $line (@lines) {
    if (my ($field, $data) = $line =~ m/^(\w+).+?(<.+?>)$/) {
        $results{$field} = $data;
    }
}

for my $field (keys %results) {
    print "$field is $results{$field}\n";
}

__DATA__
To:sanju <sip:san@36.212.176.07>
From: paka<sip:sam@36.212.176.92>
Contact: sanjay<sip:san@36.212.176.07:5060>
[download]

Contact is <sip:san@36.212.176.07:5060>
To is <sip:san@36.212.176.07>
From is <sip:sam@36.212.176.92>
[download]

The advantage of an approach such as this is that you do away with your if/else conditionals, so it becomes more scalable. For example, if you suddenly had to extract 100 sets of data instead of three, you wouldn't need to alter the code at all. But using your original approach, you'd need to add a separate conditional statement for each of the 100 possibilities.

Explaining the pattern match in that code...

($field, $data) = $line =~ m/^(\w+).+?(<.+?>)$/
[download]

• match the beginning of the string , and then start capturing (  ^()
• continue to capture as long as there are "word" characters (  \w)
• assign whatever has been captuted to $field
• match one or more of anything until we see a "<", and then start capturing again
• match one or more of anything, and keep capturing until we see a ">"
• assign this second capture to $data
• match the end of the string (  $)

The anchors (^ and $) are probably not completely necessary in this case, however it's a good habit to anchor your pattern matches where ever possible, as it speeds things up.

Hope this helps,
Darren :)