#!/usr/bin/perl
use strict;
use warnings;
use Data::Dumper;

use Marpa::R2;

my $g = << '__G__';
lexeme default = latm => 1

:start   ::= Hash
:default ::= action => itself

Hash  ::= '(' Pairs ')'     action => hash
Pairs ::= Pair+             action => pairs
Pair  ::= '(' Key Value ')' action => pair
Key   ::= String
Value ::= String
        | Pairs

String     ~ [^\s()]+
whitespace ~ [\s]+
:discard   ~ whitespace
__G__

my $grammar = 'Marpa::R2::Scanless::G'->new({ source => \$g });

my $input = '(
  (SECTION (Section_KEY Value1)
    (Another_KEY1 Value2) (KEY2 value3)
    (KEY3 Value4))
  (NEW_SECTION
    (SUB_SECTION
      (KEY4 Value5))
    (NEW_SUB_SECTION (KEY5 Value6)
    )
  )
)';

my $recce = 'Marpa::R2::Scanless::R'->new({ grammar           => $grammar,
                                            semantics_package => 'main',
                                          });

$recce->read(\$input);
print Dumper $recce->value;

sub hash   { $_[2] }
sub pairs  { shift; +{ map @$_, @_ } }
sub pair   { [ @_[2, 3] ] }
sub itself { $_[1] }