Why, when my object creates another object and passes it back, does it not work?

bobtfish has asked for the wisdom of the Perl Monks concerning the following question:

Why does this return the same value from both objects?

$baz=TESTME->new();
$foo=$baz->wibble();
warn "Foo is $foo";
sleep 5;
$bar=$baz->wibble();
warn "Bar is $bar";
warn "Foo is $foo";
print $foo->get();
print $bar->get();
print "\n";
exit;

package TESTME;

sub new {
    my $class = shift;
    my $self = {};
    bless ($self, $class);
    warn "In TESTME->new, created object $self in class $class";
    return $self;
}

sub wibble {
    my $self = shift;
    my $val = shift;
    my $object = undef;
    $object=TEST->new ;
    warn "In wibble, object $self val $val created object $object";
    return $object;
}

package TEST;

sub new {
    my $class = shift;
    my $self = {};
    bless ($self, $class);    
    $self{'date'} = `date`;
    warn "In TEST->new, created object $self, with date $self{'date'}"
+;
    return $self;
}

sub get {
    my $self = shift;
    warn "In TEST->get with object $self and date $self{'date'}";
    return($self{'date'});
}
[download]

I am really confused by it..

Comment on Why, when my object creates another object and passes it back, does it not work? Download Code

Replies are listed 'Best First'.
Re (tilly) 1: Why, when my object creates another object and passes it back, does it not work? by tilly (Archbishop) on Apr 06, 2001 at 13:03 UTC
Try adding `use strict;` [download] to the beginning and fixing the tyop it catches... UPDATE Actually it will catch multiple non-errors, and then it will notice that you were writing: `$self{'date'}` [download] where you undoubtably wanted `$self->{date}` [download]	[reply] [d/l] [select]
Re: Why, when my object creates another object and passes it back, does it not work? by ton (Friar) on Apr 06, 2001 at 21:54 UTC
I only did a quick glance through, but it looks like you are treating your hash references as though they were actual hashes. Example: sub new { my $class = shift; my $self = {}; bless ($self, $class); $self{'date'} = `date`; warn "In TEST->new, created object $self, with date $self{'date'}" +; return $self; } [download] You set $self to be a reference to an anonymous hash, then set $self{'date'} to the result of the date system call. What perl does is create a new hash, %self, and fills its 'date' key with that result. Since all variables are globals by default, this %self (not to be confused with $self) will be the same for all methods that attempt to access it. Hence, all calls to the 'get' method of TEST will return the same value regardless of instance, since the method references the global hash %self, not the private instance variable $self. So use $self->{'date'} instead of $self{'date'}, and all will be well. Also, make it a habit to 'use strict' at all times, as it will catch all sorts of bugs like this.	[reply] [d/l]

Back to Seekers of Perl Wisdom