{
   local *Class::method = sub { ... };
   ...
}
[download]

For anything in "...", called by "..." directly, or called by "..." indirectly, the method will exist.

I'm not sure doing so is a good idea, however. Why do you want to do this?

To avoid implementing in the Class a method I only need for a specific algorithm implemented using the visitor pattern.

Thx a lot.

-- Nice photos of naked perl sources here !

This sounds like something for which code references would be more suitable.

After reading up on the Visitor pattern — I wasn't familiar with it by name — I dare say it *is* something for which code references would be more suitable. The example on that paged could be implemented as follows in Perl:

use strict;
use warnings;

{
   package Wheel;

   sub new {
      my ($class, $name) = @_;
      return bless({ name => $name }, $class);
   }

   sub get_name { my ($self) = @_; return $self->{name}; }
   sub accept { my ($self, $visitor) = @_; $visitor->($self); }
}

{
   package Engine;
   sub new { my ($class) = @_; return bless({}, $class); }
   sub accept { my ($self, $visitor) = @_; $visitor->($self); }
}

{
   package Body;
   sub new { my ($class) = @_; return bless({}, $class); }
   sub accept { my ($self, $visitor) = @_; $visitor->($self); }
}

{
   package Car;

   sub new {
      my ($class) = @_;
      return bless({
         engine => Engine->new(),
         body   => Body->new(),
         wheels => [ map { Wheel->new($_) }
            'front left',
            'front right',
            'back left',
            'back right',
         ],
      }, $class);
   }

   sub accept {
      my ($self, $visitor) = @_;
      $visitor->($self);
      $self->{engine}->accept($visitor);
      $self->{body}->accept($visitor);
      $_->accept($visitor) foreach @{$self->{wheels}};
   }
}

sub visitor {
   my ($o) = @_;

   if ($o->isa('Wheel')) {
      print("Visiting ", $o->get_name(), " wheel\n");
   }
   elsif ($o->isa('Body')) {
      print("Visiting body\n");
   }
   elsif ($o->isa('Engine')) {
      print("Visiting engine\n");
   }
   elsif ($o->isa('Car')) {
      print("Visiting car\n");
   }
   else {
      die("Unknown class " . ref($o));
   }
}

{
   my $car = Car->new();
   $car->accept(\&visitor);
}
[download]

The approach shown above is a nice "lightweight" solution. If you wanted to be more industrial-grade about it, you could make a derived class which adds the new method. Delegation is another possibility.

We're building the house of the future together.

Ikegami has pre-empted me but you might want to expand on how you understand the Visitor Pattern

/J\

Do you need to add it to a class or just an instance? I like Class::Trait for either. (See my Class::Trait review.)

my $foo = Foo->new;

*Foo::bar = sub { print "bar\n"; };

$foo->bar();

undef *Foo::bar;

$foo->bar();

package Foo;

sub new { return bless {}, shift; }

1;
[download]

bar
Can't locate object method "bar" via package "Foo" at foo.pl line 9.
[download]