if ($temp =~ /#/){
        $temp =~ s/#$'//;
}
[download]

That's what's causing the problem: $' can contain arbitrary data, but you try to treat it as a regex.

The "good" solution is to use this regex instead: $temp =~ s/#.*$//;

In general you can also quote interpolated variables, then they are treated as text, not as regexes:

my $varaible = '[a-z]';
m/\Q$variable\E/  # matches literal [a-z], not a character class.
[download]

If you're not inside a regex, quotemeta does the same job.

If you would happen to have the '#' character inside a (single or double) quoted string in your config file (I don't know if the specs for your config-file even allow this) then the s/#.*$// regex will cause you trouble as it will delete all of the string starting with the '#' character. That is probably not what you want.

It is not easy to take care of this: not even Regexp::Common gets it right.

CountZero

A program should be light and agile, its subroutines connected like a string of pearls. The spirit and intent of the program should be retained throughout. There should be neither too little or too much, neither needless loops nor useless variables, neither lack of structure nor overwhelming rigidity." - The Tao of Programming, 4.1 - Geoffrey James

You probably want something like:

while (chomp(my $temp=<INPUT>)){
    print Dumper $temp;
    $temp =~ s/#.*//;  # remove comments
    if ($temp =~ /^\s*$/){
        next;
    }
    print "after regex:\n";
    print Dumper $temp;
    print "end\n";
}
[download]

Thanks both---I didn't realise that $' was treated like that. Are all 'special variables' ($&, $N (N is integer)) expanded in that way too? So if you did something like:

$temp =~ m/(\[0-9\])blah$1/;
[download]

would you match

$temp = "[0-9]blah6";
[download]

rather than

$temp = "[0-9]blah[0-9]";
[download]

?
V. interesting---I assumed that special characters inside the rest of the data would be ignored..
Cheers
<--edit to make the last sentence make more sense!-->
........
Those are my principles. If you don't like them I have others.
-- Groucho Marx
.......

Are all 'special variables' ($&, $N (N is integer)) expanded in that way too?

All variables are expanded that way, special or not:

my $var = '[ab]';
my $string = '12a3434';
print "match" if $string =~ /$var/;
[download]

See also quotemeta and the \Q and \E escape sequences.
"What should it profit a man, if he should win a flame war, yet lose his cool?"

$temp =~ m/(\[0-9\])blah$1/;
[download]

I think you meant

$temp =~ m/(\[0-9\])blah\1/;
[download]

in which case any special characters in the content of the backreference \1 would not be treated special. IOW, "[0-9]blah[0-9]" would match, but not "[0-9]blah6":

#!/usr/bin/perl

use strict;
use warnings;

for my $temp ("[0-9]blah[0-9]", "[0-9]blah6") {
    printf "%-15s ", $temp;
    if ($temp =~ /(\[0-9\])blah\1/) {
        print "matched\n";
    } else {
        print "didn't match\n";
    }
}
[download]

prints

[0-9]blah[0-9]  matched
[0-9]blah6      didn't match
[download]

while, if you replace \1 with $1 in the above regex, it prints

Use of uninitialized value in concatenation (.) or string at ./671663.
+pl line 8.
[0-9]blah[0-9]  matched
[0-9]blah6      matched
[download]

This is because $1 isn't defined here, thus the regex effectively becomes /(\[0-9\])blah/...

Update: added demo code.

while (chomp(my $temp=<INPUT>)){