Object Serialization Basics

What is serialization and why does it matter?

Taking an object in memory and making it persistent -- that is, outlasting the life of its fleeting implementation in memory. Perhaps you wish to save the state of your program to disk when it exits, and restore when it starts again. Maybe you want to transfer objects across the network to another instance of your program. You might even store objects in a database.

There are three good modules you may wish to use:

• Storable
• FreezeThaw
• Data::Dumper

my $data = "this is a string of text";
my @dataset = qw( this is an array of text );
my %datagroup = ( hash => "mine", text => "yours" );
[download]

Storable

Two main methods you'll want to study are Storable::freeze and Storable::thaw. The following is an example of their use:

use Storable;
my $stored = freeze [ \$data, \@dataset, \%datagroup ];

print $stored;    # just to see what it looks like, in binary encoding

my $thawed = thaw $stored;

my ($newdata, $newdataset_ref, $newdatagroup_ref) = @$thawed;    # cop
+ies of original variables
(*data, *dataset, *datagroup) = @$thawed;    # restore into the origin
+al variables
[download]

Other useful methods include store() and retrieve(), which provide access to a named disk file.

FreezeThaw

This also provides freeze() and thaw() methods, but the interface is slightly different:

use FreezeThaw;

my $stored = freeze (\$data, \@dataset, \%datagroup);

print $stored;    # even trickier encoding

my @thawed = thaw $stored;
my ($newdata, $newdataset_ref, $newdatagroup_ref) = @thawed;

(*data, *dataset, *datagroup) = @thawed;
[download]

The biggest difference right there is that these methods work on a list, not an anonymous array.

Even better, freeze() and thaw() called on a blessed object (what we really want to persist, right?) calls the Freeze or Thaw method, respectively, of that object. If none is provided, FreezeThaw has already installed UNIVERSAL::Freeze and UNIVERSAL::Thaw.

DataDumper

This module produces Perl output as the encoding language.

my $stored = Data::Dumper->Dump( [ $data, \@dataset, \%datagroup ],
                                 [ qw(data *dataset   *datagroup )] );

print $stored;

eval $stored;
[download]

Note that the Dump subroutine takes two anonymous arrays. The first is a list of scalars (or references) to dump, and the second is a list of variables to which to assign the dumped data. (You can leave off the second list, but you'll end up with autogenerated names like $VAR1, $VAR2, and so on.)

Dumping an object results in all of the member data of the object being stored. There's something else magical that happens, though, as evidenced by this dump of an instance of Hello::Hi (from Jellybean):

$hi = bless( {
        'Data' => {},
        'Container' => 'Container',
        'Info' => {
            'modified' => '0',
            'name' => 'Hi',
            'author' => 'chromatic',
            'date' => '1 March 2000',
            'desc' => 'silly demonstration for Jellybean'
        },
        'main' => sub { "DUMMY" },
        'say_hi' => sub { "DUMMY" }
    }, 'Hello::Hi' );
[download]

When this is run through eval() (and assuming you have Hello::Hi available in memory somewhere already), you can call the correct methods. That is, $hi->main() and $hi->say_hi() produce the expected results as if the object had not been dumped and eval()'d.

What Then?

Since these three methods all end up with encoded data stored in a scalar, you can write it to a file or stick it in a database somewhere. You can send it to another process via a pipe, over a socket, or even through an HTTP connection. Decoding it on the other side is also easy.

for more information, see the documentation for Storable, FreezeThaw, and Data::Dumper, or Object Oriented Perl.