#!/usr/bin/env perl

use strict;
use warnings;

use Inline::Files;
use XML::Simple qw{:strict};

my %xml_hash = (Data => {});
my $xml_data = $xml_hash{Data};
my (%db1, %db2);

while (<DB1>) {
    my ($root, $table, $key) = split;
    push @{$db1{$root}{$table}}, $key;
}

while (<DB2>) {
    my ($root, $table, $key) = split;
    push @{$db2{$root}{$table}}, $key;
}

while (<DIFF>) {
    my ($root, $table, $key, $col, $old, $new) = split;
    $xml_data->{$root}{$table}{NEW1}{KEY} = $db1{$root}{$table}
        if exists $db1{$root}{$table};
    $xml_data->{$root}{$table}{NEW2}{KEY} = $db2{$root}{$table}
        if exists $db2{$root}{$table};
    $xml_data->{$root}{$table}{MODIFIED}{KEY}{$key}{$col}{oldvalue} = [$old];
    $xml_data->{$root}{$table}{MODIFIED}{KEY}{$key}{$col}{newvalue} = [$new];
}

print XMLout(\%xml_hash, KeepRoot => 1, KeyAttr => {KEY => 'name'});

__DIFF__
Root1      TBLA      KEY1      COLA      A    B    
Root1      TBLA      KEY1      COLB      D    E    
Root1      TBLA      KEY3      COLX      M    N     
Root2      TBLB      KEY4      COLX      M    N     
Root2      TBLB      KEY4      COLD      A    B   
Root3      TBLC      KEY5      COLD      A    B 
__DB1__
Root1      TBLA      KEY6    
Root2      TBLB      KEY7    
Root3      TBLC      KEY8 
__DB2__
Root1      TBLA      KEY9    
Root1      TBLA      KEY10    
Root3      TBLC      KEY11 

##</code><code>##

$ pm_xml_db_diff.pl
<Data>
  <Root1>
    <TBLA>
      <MODIFIED>
        <KEY name="KEY1">
          <COLA>
            <newvalue>B</newvalue>
            <oldvalue>A</oldvalue>
          </COLA>
          <COLB>
            <newvalue>E</newvalue>
            <oldvalue>D</oldvalue>
          </COLB>
        </KEY>
        <KEY name="KEY3">
          <COLX>
            <newvalue>N</newvalue>
            <oldvalue>M</oldvalue>
          </COLX>
        </KEY>
      </MODIFIED>
      <NEW1>
        <KEY>KEY6</KEY>
      </NEW1>
      <NEW2>
        <KEY>KEY9</KEY>
        <KEY>KEY10</KEY>
      </NEW2>
    </TBLA>
  </Root1>
  <Root2>
    <TBLB>
      <MODIFIED>
        <KEY name="KEY4">
          <COLD>
            <newvalue>B</newvalue>
            <oldvalue>A</oldvalue>
          </COLD>
          <COLX>
            <newvalue>N</newvalue>
            <oldvalue>M</oldvalue>
          </COLX>
        </KEY>
      </MODIFIED>
      <NEW1>
        <KEY>KEY7</KEY>
      </NEW1>
    </TBLB>
  </Root2>
  <Root3>
    <TBLC>
      <MODIFIED>
        <KEY name="KEY5">
          <COLD>
            <newvalue>B</newvalue>
            <oldvalue>A</oldvalue>
          </COLD>
        </KEY>
      </MODIFIED>
      <NEW1>
        <KEY>KEY8</KEY>
      </NEW1>
      <NEW2>
        <KEY>KEY11</KEY>
      </NEW2>
    </TBLC>
  </Root3>
</Data>