:
#! perl -slw
use strict;
use Benchmark qw[ cmpthese ];

our $N //= 1e3;
our $I //= -1;

our @as;
@{ $as[ $_ ] } = 1 .. $N for 0 .. 4;

cmpthese $I, {
    for_splice => q[
        my $ar = $as[0];
        $ar->[$_] =~ /9/ and splice @$ar, $_, 1 for reverse 0 .. $#$ar;
        $I == 1 and print "0: ", "@$ar";
    ],
    grep => q[
        my $ar = $as[1];
        @$ar = grep !/9/, @$ar;
        $I == 1 and print "1: ", "@$ar";
    ],
    offset_copy => q[
        my $ar = $as[2];
        my $o = 0;
        for( 0 .. $#$ar ) {
            $ar->[$_-$o] = $ar->[$_];
            $ar->[ $_ ] =~ /9/ and ++$o;
        }
        $#$ar = $#$ar - $o;
        $I == 1 and print "2: ", "@$ar";
    ],
    build_new_array=>q[
        my $ar = $as[3];
        my @b;
        for( @$ar ) {
            push @b, $_ unless /9/;
        }
        $I == 1 and print "3: ", "@b";
    ],
    edit_in_place=>q[
        my $ar = $as[4];
        my $o = 0;
        for( @$ar ) {
            $ar->[$o++] = $_ unless /9/;
        }
        $#$ar = $o - 1;
        $I == 1 and print "4: ", "@$ar";
    ],
};