use strict;
use warnings;

print_ranges(make_ranges(make_sets(<DATA>)));

exit 0;

sub make_sets {
    my @lists = @_;
    my %set_by; # Hash of sets of integers by labels

    for my $list (@lists) {
        while ($list =~ m/(\w+)\s*:\s*(\d+)(?:\s*-\s*(\d+))?/ag) {
            my $label = $1;
            my $start = $2;
            my $end   = $+;

            for my $integer ($start .. $end) {
                $set_by{$label}{$integer} = 1;
            }
        }
    }

    return \%set_by;
}

sub make_ranges {
    my $set_by = shift;
    my %ranges_by; # Hash of arrays of integer ranges by labels

    for my $label (keys %$set_by) {
        my $index = 0;

        for my $integer (sort { $a <=> $b } keys %{ $set_by->{$label} }) {
            if (not exists $set_by->{$label}{$integer - 1}) {
                $ranges_by{$label}[$index]{START} = $integer;
            }

            if (not exists $set_by->{$label}{$integer + 1}) {
                $ranges_by{$label}[$index++]{END} = $integer;
            }
        }
    }

    return \%ranges_by;
}

sub print_ranges {
    my $ranges_by = shift;
    my @ranges;

    for my $label (sort keys %{ $ranges_by }) {
        for my $range (@{ $ranges_by->{$label} }) {
            my $start = $range->{START};
            my $end   = $range->{END};

            push @ranges,
                $start == $end ? "$label:$start" : "$label:$start-$end";
        }
    }

    print join(' ', @ranges) . "\n";
}

__DATA__
a:10-34 b:9-12 c:12-24 e: 1-9
a:1-8 a: 19-24 b:2-6
a:7-11 d:9-23 e: 12-23
a:35 e : 20 - 28 foo:42