#!/usr/bin/perl
use 5.018;
use strict;
use warnings;
use XML::Twig;

{
  my $t;
  my $pos = tell 'DATA'; # save the offset...
  
  # Process fruit
  open (my $FRUIT, '>', './fruit.xml') or die "./fruit.xml:\n$!\n$^E";
  $t = XML::Twig->new(
    twig_handlers => {
      'thing'      => sub { _filter(@_, 'fruit', $FRUIT); 1; },
      'thing//*'   => sub { 1; },
      '_default_'  => sub { $_[0]->flush($FRUIT); 1; },
      '#CDATA'     => sub { 1; },
    },
    pretty_print => 'indented',
    comments     => 'drop',  # remove any comments
    empty_tags   => 'normal',# empty tags = <tag/>
  );
  
  $t->parse(*DATA);
  close $FRUIT;
  
  seek 'DATA', $pos, 0; # reset DATA for the second run-through
  
  # Process vegetables
  open (my $VEG, '>', './veg.xml') or die "./veg.xml:\n$!\n$^E";
  $t = XML::Twig->new(
    twig_handlers => {
      'thing'     => sub { _filter(@_, 'vegetable', $VEG); 1; },
      'thing//*'  => sub { 1; },
      '_default_' => sub { $_[0]->flush($VEG); 1; },
      '#CDATA'    => sub { 1; },
    },
    pretty_print => 'indented',
    comments     => 'drop',  # remove any comments
    empty_tags   => 'normal',# empty tags = <tag/>
  );
  
  $t->parse(*DATA);
  close $VEG;
}

sub _filter {
  my ($_twig, $thing_element, $keep_me, $PRINT_FILE) = @_;
  
  # Flush the twig to file if the 'type' attribute matches...
  if ( $thing_element->{att}{type} eq $keep_me ) {
    $_twig->flush($PRINT_FILE);
  }
  
  # ... otherwise delete the twig
  else {
    $thing_element->delete();
  }
  
  return 1;
}

__DATA__
<batch>
  <header>
    <foo>1</foo>
    <bar>2</bar>
    <baz>3</baz>
  </header>
  <thing type="fruit"     >Im an apple!</thing>
  <thing type="city"      >Toronto</thing>
  <thing type="vegetable" >Im a carrot!</thing>
  <thing type="city"      >Melrose</thing>
  <thing type="vegetable" >Im a potato!</thing>
  <thing type="fruit"     >Im a pear!</thing>
  <thing type="vegetable" >Im a pickle!</thing>
  <thing type="city"      >Patna</thing>
  <thing type="fruit"     >Im a banana!</thing>
  <thing type="vegetable" >Im an eggplant!</thing>
  <thing type="city"      >Taumatawhakatangihangakoauauotamateaturipukakapikimaungahoronukupokaiwhenuakitanatahu</thing>
  <trailer>
    <chrzaszcz>A</chrzaszcz>
    <zdzblo>B</zdzblo>
  </trailer>
</batch>

##</code><code>##

perl -v

This is perl 5, version 18, subversion 2 (v5.18.2) built for MSWin32-x64-multi-thread
(with 1 registered patch, see perl -V for more detail)

##</code><code>##

perl -MXML::Twig -E "say $XML::Twig::VERSION;"
3.48