#!/usr/bin/perl -w
# AoH_count.pl --- Perlmonks: Counting elements in array of cases
# Link:    https://perlmonks.org/?node_id=11106779
# Author:  <LanX>
# Created: 27 Sep 2019
# Version: 0.03

use warnings;
use strict;
use Test::More;
use List::Util qw/uniq/;


sub transform {
    my @in_ah = @_;                     # AoH
    my @out_ah;                         # AoH
    
    my @target_order;
    my %count;
    my %origin_ha;                      # HoA

    # --- colums to rows by target
    for my $h ( @in_ah ) {
        my $target = $h->{targetL};
        
        push @target_order, $target;
        $count{$target} += $h->{count}; # not ++, input-count might not be 1
        push @{ $origin_ha{$target} }, $h->{origin};
    }

    # --- rows to columns
    for my $target ( uniq @target_order ) {
        push @out_ah,
            {
                targetL => $target,
                origin  => join ( " ", uniq @{ $origin_ha{$target} } ),
                count   => $count{$target},
            };
    }

    return @out_ah;
}

# ---------- tests

my @AoHfinal = transform (
	{'targetL' => 'foisonnement', 'origin' => 'AMG', 'count' => '1'},
	{'targetL' => 'foisonnement', 'origin' => 'IDBR', 'count' => '1'},
	{'targetL' => 'gonfler', 'origin' => 'IWWF', 'count' => '1'},
	{'targetL' => 'due', 'origin' => 'IWWF', 'count' => '1' },
	{'targetL' => 'due', 'origin' => 'IWWF', 'count' => '1' },
);

is_deeply \@AoHfinal, [
	{'targetL' => 'foisonnement','origin' => 'AMG IDBR','count'=>'2'},
	{'targetL' => 'gonfler','origin' => 'IWWF','count' => '1'},
	{'targetL' => 'due','origin' => 'IWWF','count' => '2'},
] or diag explain \@AoHfinal;

done_testing;