#!/usr/bin/perl
use strict;
use warnings;
use autodie;

print 'Please enter protein sequence filename: ';
chomp( my $prot_filename = <STDIN> );

open my $PROTFILE, '<', $prot_filename;

my $report_name = "${prot_filename}_alanine_report";
open my $out_file, '>', $report_name;

my $rx_fasta_header = qr{ \A > }xms;  # header pattern - very naive
my $rx_sequence     = qr{ \A [ACDEFGHIKLMNPQRSTVWY_]+ \z }xms;  # please check
my $rx_blank_line   = qr{ \A \s* \z }xms;

my $sequence;  # sequence accumulator - initially undefined

RECORD:
while (my $record = <$PROTFILE>) {

    # handle any records to be ignored here
    next RECORD if $record =~ $rx_blank_line;

    chomp $record;  # get rid of newline, if any

    # fasta header - process any sequence accumulated so far
    if ($record =~ $rx_fasta_header) {
       
        # do not process if no sequence accumulated so far (i.e., first header)
        next RECORD if not defined $sequence;
       
        do_something_with($sequence, $out_file);
       
        undef $sequence;  # prepare to process next sequence
        next RECORD;
       
        }

    # part of sequence - accumulate
    if ($record =~ $rx_sequence) {
        $sequence .= $record;  # accumulate sub-sequences (records)
        next RECORD;
        }

    die "bad record: '$record'";  # don't know what this is

    }  # end while RECORD loop

# handle any sequence accumulated from final FASTA record
do_something_with($sequence, $out_file) if defined $sequence;

# clean up
close $PROTFILE;
close $out_file;

exit;

# subroutines #

sub do_something_with {

    my ($sequence,  # accumulated sequence
        $fh,        # output filehandle
        ) = @_;

    my $seq_len = length $sequence;
    }