# rtoa-pgatram-mce.pl
# Example run: perl rtoa-pgatram-mce.pl t1.txt >mce.tmp
#
# Convert a "modern" Roman Numeral to its arabic (decimal) equivalent.
# The alpabetic input string may be assumed to always contain a valid Roman Numeral in the range 1-3999.
# Roman numerals may be upper or lower case.
# Error handling is not required.
# For example:
#    input "XLII" should produce the arabic (decimal) value 42
#    input "mi"   should produce the arabic (decimal) value 1001

use strict;
use warnings;
use List::Util qw(reduce);
use Time::HiRes qw(time);
use MCE;

# Function roman_to_arabic
# Output a list of their arabic (decimal) values to standard output.
#
sub roman_to_arabic {
   my $files = shift;    # in:  reference to a list of files containing Roman Numerals (one per line)
   my %rtoa = ( M=>1000, D=>500, C=>100, L=>50, X=>10, V=>5, I=>1 );

   # construct a pool of workers
   my $mce = MCE->new(
      max_workers => MCE::Util::get_ncpu(),
      chunk_size  => 90 * 1024,
      init_relay  => 1,   # if defined, tells MCE to load MCE::Relay plus extra setup
      posix_exit  => 1,
      user_func   => sub {
         my ( $mce, $chunk_ref, $chunk_id, $output ) = ( @_, '' );
         chomp @{$chunk_ref};
         for ( @{$chunk_ref} ) {
          # $output .= reduce { $a+$b-$a%$b*2 } map { $rtoa{$_} } split //, uc($_);
            $output .= reduce { $a+$b-$a%$b*2 } @rtoa{ split //, uc($_) };
            $output .= "\n";
         }
         # output orderly
         MCE::relay { print $output };
      }
   );

   # process a list of files
   for my $fname ( @{$files} ) {
      warn("$0: cannot access '$fname': No such file or directory\n"), next
         unless -e $fname;
      warn("$0: cannot access '$fname': Permission denied\n"), next
         unless -r $fname;
      warn("$0: cannot process '$fname': Is a directory\n"), next
         if -d $fname;
      $mce->process({ input_data => $fname });
   }

   # reap MCE workers
   $mce->shutdown;
}

@ARGV or die "usage: $0 file...\n";
my @rtoa_files = @ARGV;

warn "rtoa pgatram start\n";
my $tstart = time;
roman_to_arabic(\@rtoa_files);
warn sprintf("time %0.03f secs\n", time - $tstart);