package QDMatrix;
use v5.36;
sub new($class, $n_minor, $values) {
	if (ref $values->[0]) {
		$#{$values->[$_]} == $n_minor or die "Irregular column len in matrix: $#{$values->[$_]} != $n_minor"
			for 0..$#$values;
		$values= [ @$values ];
	} else {
		@$values % $n_minor == 0
			or die "Un-rectangular number of values in data: ".scalar(@$values)." / $n_minor = ".(@$values/$n_minor);
		$values= [
			map [ @{$values}[$_*$n_minor .. ($_+1)*$n_minor-1] ],
				0 .. int($#$values/$n_minor)
		]
	}
	bless $values, $class;
}
sub flatten($self) {
	map @$_, @$self
}
sub clone($self) {
	bless [ map [ @$_ ], @$self ], ref $self;
}
sub dims($self) { scalar @$self, scalar @{$self->[0]} }
sub major($self, $i) { @{$self->[$i]} }
sub minor($self, $i) { map $_->[$i], @$self }
sub mul($self, $m2) {
	my ($maj, $min)= $self->dims;
	my ($m2_maj, $m2_min)= $m2->dims;
	$min == $m2_maj
		or die "Incompatible matrix sizes: ($maj,$min) X ($m2_maj,$m2_min)";
	my @ret;
	for my $i (0 .. $maj-1) {
		for my $j (0 .. $m2_min-1) {
			my $sum= 0;
			$sum += $self->[$i][$_] * $m2->[$_][$j] for 0 .. $min-1;
			$ret[$i][$j]= $sum;
		}
	}
	bless \@ret, ref $self;
}
sub transpose($self) {
	bless [ map [ $self->minor($_) ], 0 .. $#{$self->[0]} ], ref $self;
}


my $identity= QDMatrix->new(3, [ 1,0,0, 0,1,0, 0,0,1 ]);
my $x= QDMatrix->new(3, [ 4,5,1 ])->mul($identity->mul(QDMatrix->new(3, [ 1,0,0, 0,1,0, 2,0,1 ])));
use DDP; p $x;