#!/usr/bin/env perl

use v5.34;
use warnings;
use experimental 'signatures';
use autodie;
use constant {
    SEP1 => "\n" . '=' x 40,
    SEP2 => '-' x 40,
};

use Benchmark 'cmpthese';
use File::Spec ();

my ($null_fh, $base_str);
BEGIN {
    open $null_fh, '>', File::Spec::->devnull();
    $base_str = <<~'EOT';
        AdataA
        BdataB
        CdataC
        EOT
}

my @bench_names = qw{net1 net2 hau1 ner1 ner2 kco1 kco2 net3};
my (%bench_for, %benches_to_cmp, $mult_str);
say 'Test', SEP1;

for my $bench (@bench_names) {
    no strict 'refs';
    ($bench_for{$bench} = \&{$bench})->(\$base_str);
    use strict 'refs';
    say SEP2;

    $benches_to_cmp{$bench} = sub {
        $bench_for{$bench}->(\$mult_str, $null_fh);
    };
}

for my $mult (1, 10, 100, 1_000, 10_000) {
    $mult_str = $base_str x $mult;
    say 'Bench (Length: ', length($mult_str), ')', SEP1;
    cmpthese 0 => \%benches_to_cmp;
    say SEP2;
}

sub net1 ($rstr, $out_fh = *STDOUT) {
    my $str = $$rstr;

    while ($str =~ /(^A|^B)(.+)$/mg) {
        $out_fh->say("$1 net1 $2");
    }

    return;
}

sub net2 ($rstr, $out_fh = *STDOUT) {
    my $str = $$rstr;

    open my $fh, '<', \$str;

    while (<$fh>) {
        my ($name, $data) = m/(^A|^B)(.+)$/ or next;
        $out_fh->say("$name net2 $data");
    }

    return;
}

sub hau1 ($rstr, $out_fh = *STDOUT) {
    my $str = $$rstr;

    while ($str =~ m{^ (?<name>A|B) (?<data>.+) $}xmg) {
        $out_fh->say("$+{name} hau1 $+{data}");
    }

    return;
}

sub ner1 ($rstr, $out_fh = *STDOUT) {
    my $str = $$rstr;

    $out_fh->say("$1 ner1 $2") while $str =~ /^([AB])(.+)$/mg;

    return;
}

sub ner2 ($rstr, $out_fh = *STDOUT) {
    my $str = $$rstr;

    $str =~ /^([AB])(.++)$(?{ $out_fh->say("$1 ner2 $2") })./m;

    return;
}

sub kco1 ($rstr, $out_fh = *STDOUT) {
    my $str = $$rstr;
    my $re = qr{(?m:^([AB])(.+)$)};

    $out_fh->say("$1 kco1 $2") while $str =~ /$re/g;

    return;
}

sub kco2 ($rstr, $out_fh = *STDOUT) {
    my $str = $$rstr;
    my $re = qr{(?m:^([AB])(.+)$)};

    $out_fh->say("$1 kco2 $2") while $str =~ /$re/go;

    return;
}

sub net3 ($rstr, $out_fh = *STDOUT) {
    my $str = $$rstr;
    my $re = qr{(?m:^(A|B)(.+)$)};

    while ($str =~ /$re/go){
        $out_fh->say("$1 net3 $2");
    }

    return;
}