#!/usr/bin/env -S perl
##!/usr/bin/env -S perl -d

#
# Script to exercise Perl Tkx/Tcl bindings
#
use warnings;
use strict;
use v5.30;
use feature ":all";
use Math::BigInt;
use Tkx;

sub factorial {
  my ($n) = @_;
  return 1 if $n == 0;
  no warnings 'recursion';
  return factorial($n-1) * $n
}

my $mw = Tkx::widget->new(".",);
$mw->g_wm_title("Tkx Factorial Calculator");

my $result;
my $value;
my $e = $mw->new_entry(
    -width        => 6,
    -relief       => 'sunken',
    -textvariable => \$value,
);

my $calculate = sub {
    # Stringify to prevent the conversion to int or float!
    say $value;
    $result = "" . factorial(Math::BigInt->new($value));
    say $result;
};

my $desc = $mw->new_label(-text => 'Factorial is:',);
my $r    = $mw->new_label(-textvariable => \$result,);
my $blk  = $mw->new_label(-text => '', -width => 8,);
my $calc = $mw->new_button(-text => 'Calculate', -command => $calculate);
my $q    = $mw->new_button(-text => 'QUIT', -command => sub { $mw->g_destroy; },);

Tkx::grid($blk, $e, $desc, $r, -padx => 10, -pady => 10);
Tkx::grid($calc, -column=>3,   -padx => 10, -pady => 10);
Tkx::grid($q, '-', '-',        -padx => 10, -pady => 15);

$e->g_bind('<Return>', $calculate);
$e->g_focus();

Tkx::MainLoop;

__END__