#!/usr/bin/perl

use strict;
use warnings;
use Benchmark 'cmpthese';

my $target = 'abc' x 1e4;

cmpthese(-1,{
	'y' => 		sub { my $m = 0; $m = $target =~ y/a//; },
	'=()=' => 	sub { my $m = 0; $m = () = $target =~ m/a/g; },
	'while' => 	sub { my $m = 0; $m ++ while $target =~ m/a/g; },
	'(?{})' => 	sub { my $m = 0; $target =~ m/a(?{ $m ++ })(*F)/g; },
	'split_grep' => sub { my $m = 0; 
		$m = grep $_ eq 'a', split '', $target; 
		},
	'split_by' => sub { my $m = 0; 
		$m = -1 + split 'a', 'x' . $target . 'x'; 
		},
	'chop' => 	sub { my $m = 0; 
		my $target2 = $target;
		$m += ( 'a' eq chop $target2 ) while length $target2; 
		},
	'chomp' => 	sub { my $m = 0; 
		my $target2 = $target;
		local $/ = 'a';
		0 while chomp $target2 and ++ $m or chop $target2;
		},
	'index' => 	sub { my $m = 0; 
		my $pat_len = length 'a';
		my $pos = -$pat_len;
		$m ++ while -1 < ( $pos = index $target, 'a', $pos + $pat_len );
		},
	'rindex' => 	sub { my $m = 0; 
		my $pat_len = length 'a';
		my $pos = -1 + length $target;
		$m ++ while -1 < ( $pos = rindex $target, 'a', $pos - $pat_len );
		},
	'substr' => 	sub { my $m = 0; 
		$m += ( 'a' eq substr $target, $_, 1 ) for 0 .. -2 + length $target;
		},
});