#!/usr/bin/perl
use warnings;
use strict;
use feature qw{ say };

use threads;
use threads::shared;

my  $done :shared;

my $t = 'threads'->create(sub {
    my %count;
    my $l2 = 'LanX'->new(42);  # <- You can move this into the below loop, too.
    until ($done) {
        ++$count{ $l2->{value} };
    }
    for my $key (keys %count) {
        say "$key: $count{$key}";
    }
});

{   package LanX;
    use overload '%{}' => \&_nothing,
                 '""'  => sub {
                              $_[0]->_underload(\&_value)
                          };

    sub new {
        bless {value => $_[1]}, $_[0]
    }

    sub inc {
        $_[0]->_underload(sub { ++$_[0]->{value} })
    }

    sub value {
        $_[0]->_underload(\&_value)
    }

    sub _nothing { { value => 'nothing' } }

    sub _value { $_[0]->{value} }

    sub _underload {
        my ($self, $sub) = @_;
        overload->unimport('%{}');
        my $v = $self->$sub;
        sleep 1 if 0 == threads->tid;
        overload->import('%{}' => \&_nothing);
        return $v
    }

}

my $l = 'LanX'->new(12);
say "deref\t" => $l->{value};  # nothing
say "l\t"     => $l;           # 12
say "deref\t" => $l->{value};  # nothing
say "inc\t"   => $l->inc;      # 13
say "l\t"     => $l;           # 13
say "inc\t"   => $l->inc;      # 14
say "l\t"     => $l;           # 14
say "deref\t" => $l->{value};  # nothing

$done = 1;
$t->join;

##</code><code>##

    sub _underload {
        my ($self, $sub) = @_;
        my $class = ref $self;
        bless $self, 'Cancel::LanX::So::We::Can::Dereference';
        my $v = $self->$sub;
        sleep 1 if 0 == threads->tid;
        bless $self, $class;
        return $v
    }