#!/usr/bin/perl

use strict; # https://perlmonks.org/?node_id=11162546
use warnings;
$SIG{__WARN__} = sub { die @_ };

# Is there a better way to get an inverse slice than to do something like:

my @array = ('aa'..'zz');
my @slice_idx = (6,13,42,66,69);
# Slice
my @slice = @array[@slice_idx];

use Data::Dump 'dd'; dd { 'array' => \@array,
  'slice_idx' => \@slice_idx, 'slice' => \@slice };

my %slice_idx = map { $_ => 1 } @slice_idx;
my @invslice_idx = grep { ! exists $slice_idx{$_} } 0 .. $#array;
# Inverse slice.
my @invslice = @array[@invslice_idx];
use Data::Dump 'dd'; dd { 'idx' => \@invslice_idx, 'invslice' => \@invslice };

my @newinvslice = @array;
@newinvslice[@slice_idx] = ();
@newinvslice = grep defined, @newinvslice;
use Data::Dump 'dd'; dd { 'newinvslice' => \@newinvslice };

use List::Util qw( none );
my @new2invslice = @array[
  grep { my $idx = $_; none { $idx == $_ } @slice_idx } 0 .. $#array ];
use Data::Dump 'dd'; dd  { 'new2invslice' => \@new2invslice };

my @new3invslice = @array;
splice @new3invslice, $_, 1 for reverse @slice_idx;
use Data::Dump 'dd'; dd  { 'new3invslice' => \@new3invslice };

use List::Util qw( uniq );
my @new4invslice =
  @array[ (uniq @slice_idx, 0 .. $#array)[@slice_idx .. $#array ] ];
use Data::Dump 'dd'; dd  { 'new4invslice' => \@new4invslice };