#! /usr/bin/perl -w
########################################################################
# File   :  Perl Schwartzian Transform Demo.pl
# History:  16-Mar-2015 Laszlo first version.
#			19-Mar-2015 Laszlo, improved a little bit.
########################################################################
# A script to demonstrate and measure the Schwartzian Transform.
########################################################################
# Some form of documentation:
# http://www.perlmonks.org/?node_id=1120222

use warnings;
use strict;
use Time::HiRes;

my $maxNumberValue = 100;
my $intSampleSize = 32000;
my @unsortedIntArray = map { int(rand($maxNumberValue)) } ( 1..$intSampleSize );

my $compareAsNumberFunction = sub { return $_[0] <=> $_[1]; };
my $compareAsStringFunction = sub { return $_[0] cmp $_[1]; };

my $noTransformFunction = sub { return shift; };
my $sleepyNoTransformFunction = sub { Time::HiRes::usleep(1); return shift; };
my $returnLengthFunction = sub { return length(shift); };

schwartzianSortVsRegularSort(\@unsortedIntArray, $compareAsNumberFunction, $noTransformFunction);
schwartzianSortVsRegularSort(\@unsortedIntArray, $compareAsStringFunction, $noTransformFunction);
schwartzianSortVsRegularSort(\@unsortedIntArray, $compareAsNumberFunction, $sleepyNoTransformFunction);

my @chars = ("A".."Z", "a".."z");
my $maxStringLength = 300;
my $stringSampleSize = 32000;
my @unsortedStringArray = map { (sub { my $string; $string .= $chars[rand @chars] for 1..(int(rand($maxStringLength)) + 1); return $string;})->();  } ( 1..$stringSampleSize );

schwartzianSortVsRegularSort(\@unsortedStringArray, $compareAsStringFunction, $noTransformFunction);
schwartzianSortVsRegularSort(\@unsortedStringArray, , $compareAsNumberFunction, $returnLengthFunction);

sub schwartzianSortVsRegularSort
{
	my @unsortedArray_in = @{$_[0]};	
	my $compareFunction_in = $_[1];
	my $transform4Sort_in = $_[2];
	
	print "Collection of size: " . +@unsortedArray_in . " \n";
	
	# Schwartzian sort, Schwartzian sort, Schwartzian sort, Schwartzian sort, Schwartzian sort
	##########################################################################################
	my $schwartzianStart = Time::HiRes::time;
	my @schwartzianSorted = map  { $_->[0] }
				 sort { $compareFunction_in->($a->[1], $b->[1]) }
				 map  { [$_, $transform4Sort_in->($_)] }
				 @unsortedArray_in;
	my $schwartzianDuration = Time::HiRes::time - $schwartzianStart;

	# Regular sort, Regular sort, Regular sort, Regular sort, Regular sort, Regular sort
	##########################################################################################
	my $regularStart = Time::HiRes::time;
	my @regularSorted = sort { $compareFunction_in->($transform4Sort_in->($a), $transform4Sort_in->($b)) } @unsortedArray_in;
	my $regularDuration = Time::HiRes::time - $regularStart;
	
	print "Execution time of the Schwartzian Transform: $schwartzianDuration s\n";
	print "Execution time of the Regular     Transform: $regularDuration s\n";

	if (!(@schwartzianSorted ~~ @regularSorted))
	{
		die "Collections are not equal!"
	}

	#print join("; ", @schwartzianSorted);
}