use strict;
use warnings;
use Parallel::ForkManager;
use IPC::Open3 qw( open3 );
use POSIX      qw( WNOHANG );
use constant TIMEOUT => 120;

my @runArray = ("test1.sh", "test2.sh", "test3.sh", "test4.sh", "test5.sh");
my ($pid, $exitCode, $ident);
my $currentTime;

my $forkMgr = Parallel::ForkManager->new(3);

$forkMgr->run_on_start(
    sub {
        ($pid, $ident) = @_;
        print "$currentTime Started ==> $ident\n";
    }
);

$forkMgr->run_on_finish(
    sub {
        ($pid, $exitCode, $ident) = @_;
        print "$currentTime Ended ==> $ident\n";
    }
);

while (1) {
    $currentTime = localtime();
    for my $runCommand (@runArray) {
        $forkMgr->start($runCommand) and next;

        my $pid = open3('<&STDIN', '>&STDOUT', '>&STDERR',
                        "/usr/localcw/opt/patrol/nagios/libexec/$runCommand");
        wait_for_test_to_end($pid);
        $forkMgr->finish($? & 0x7F ? 0x80 | ($? & 0x7F) : $? >> 8);
    }

    $forkMgr->wait_all_children;

    sleep 10;
}

exit;


sub wait_for_test_to_end {
    my ($pid) = @_;

    my $abs_timeout = time() + TIMEOUT;
    while (1) {
        return if waitpid($pid, WNOHANG) > 0;
        last if time() > $abs_timeout;
        sleep(1);
    }

    kill(ALRM => $pid);

    $abs_timeout = time() + 15;
    while (1) {
        return if waitpid($pid, WNOHANG) > 0;
        last if time() > $abs_timeout;
        sleep(1);
    }

    kill(KILL => $pid);
    waitpid($pid, 0);
}