c:\@Work\Perl\monks>perl -wMstrict -le
"use 5.010;
 ;;
 use Test::More 'no_plan';
 ;;
 my $s = '1 , 2, 3, 4 is four, 5, 6 test 00,11 is one,22,  33 is three,44,'
       . '55 is  the best, and  this  is not a test 111, 222, 333 as random  '
       . 'words to finish'
       ;
 print qq{[[$s]]};
 ;;
 my @expected = (11, 22, 33, 44, 55, 222, 333);
 ;;
 my $is   = qr{ \s+ is           \b }xms;
 my $word = qr{ \s+ [[:alpha:]]+ \b }xms;
 ;;
 my $sep = qr{ (?: $is $word?)? \s* , \s* }xms;
 ;;
 my $extract = qr{
   (?: (?: \G (?<! \A)) | test \s+ \d+) $sep
   \K \d+
   }xms;
 ;;
 my @got;
 ;;
 @got = $s =~ m{ $extract }xmsg;
 is_deeply \@got, \@expected, qq{(@got)};
 ;;
 @got = 'this line has nothing, nothing, nothing...' =~ m{ $extract }xmsg;
 is_deeply \@got, [], 'empty';
 ;;
 @got = 'this should be a test, with nothing returned 444, 777, 999 is junk'
   =~ m{ $extract }xmsg;
 is_deeply \@got, [], 'also empty';
"
[[1 , 2, 3, 4 is four, 5, 6 test 00,11 is one,22,  33 is three,44,55 is  the best, and  this  is not
 a test 111, 222, 333 as random  words to finish]]
ok 1 - (11 22 33 44 55 222 333)
ok 2 - empty
ok 3 - also empty
1..3