sub cge_start {
  my($arg_ref) = @_;

  #=+ iterate over provided config and replace defaults
  while(my($k,$v) = each %$arg_ref) {
    #=+ Replace each default value if the key exists.  Perhaps paranoid, but prevent arbitrary/unexpected settings
    $arguments{$k} = $v if exists $arguments{$k};
  }

  #=+ Make sure we have a bare minimum of settings
  return undef if $arguments{dataDir} eq '' || !-d $arguments{dataDir} || $arguments{imagesPerNode} eq '' || $arguments{nodeCount} eq '';

  #=+ Create the results directory
  #   make sure that our directory has a trailing slash "/"
  $arguments{dataDir} .= '/' unless $arguments{dataDir} =~ m/\/$/;

  #=+ Create the results directory if it does not exist
  mkdir $arguments{dataDir}.'results', 0744 if !-d $arguments{dataDir}.'results';
  $arguments{resultDir} = $arguments{dataDir}.'results';

  #=+ Create a temporary directory to store all the junk files we create for easy cleanup later
  mkdir $arguments{dataDir}.'temp', 0744 if !-d $arguments{dataDir}.'temp';

  #=+ Create the logfile string (does not need to exist)
  $arguments{logFile} = $arguments{dataDir}.'cge_logfile.log';

  #=+ Make sure we have both the number of instances and number of desired nodes
  return (undef,undef) unless $arguments{imagesPerNode} > 0 && $arguments{nodeCount} > 0;

  #=+ Create a cleanup script that we will use to kill "this" server session
  $arguments{cleanupScript} = $arguments{dataDir}.'temp/cleanup.sh';

  #=+ Make sure we have a free TCP port to use
  my $port = 3750;
  if(check_port($port)) {
    $port++;
    while(check_port($port)) {
      $port++;
    }
  }
  $arguments{queryPort} = $port;

  #=+ Concatenate all the non-blank command line arguments
  my @args;
  while(my($k,$v) = each %arguments) {
    push @args, '--'.$k.' '.$v.' ' unless $v eq '';
  }
  my $arg_string = join('',@args);

  #=+ Run the launcher
  #exec($cge_launch.' '.$arg_string.'> /dev/null 2>&1 &');
  my $success = run(command => $cge_launch.' '.$arg_string.' > '.$arguments{dataDir}.'temp/stdout.txt 2>&1 &', verbose => 0);

  #=+ Something went wrong, so just return undef
  return (undef,undef) unless $success;

  my $file = File::Tail->new($arguments{dataDir}.'temp/stdout.txt');
  while(my $line = $file->read) {
    last if $line =~ m/Starting port forwarding/;
  }

  open(my $CU,'<',$arguments{cleanupScript}) or croak $!;
  my $text = <$CU>;
  close($CU);

  my $pid;
  if($text =~ m/scancel (\d+)/m) {
    $pid = $1;
  }
  return ($pid,$port);
}