c:\@Work\Perl\monks>perl -le
"use warnings;
 use strict;
 ;;
 use Test::More 'no_plan';
 use Test::NoWarnings;
 ;;
 use Data::Dump qw(dd);
 use List::Util qw(shuffle);
 ;;
 use constant GRT_DECORATION => 'a N a N';
 use constant {
   DECORATOR   => qq{   ${ \GRT_DECORATION }   N},
   UNDECORATOR => qq{x[ ${ \GRT_DECORATION } ] N},
   };
 ;;
 my @matrix = (
   [ qw(A1a1  img1 x123 y123) ],
   [ qw(A21a1 img8 x888 y888) ],
   [ qw(A1a2  img2 x123 y456) ],
   [ qw(A2a1  img9 x999 y999) ],
   [ qw(B2a1  img7 x777 y777) ],
   [ qw(A1a12 img3 x456 y789) ],
   [ qw(A10a1 img4 x456 y123) ],
   [ qw(A12a1 img5 x456 y456) ],
   );
 ;;
 sub decorate {
   my ($i, $ar) = @_;
   ;;
   my $sort_field = $ar->[$i][0];
   my @sort_subfields = $sort_field =~ m{
       \A ([[:upper:]]) (\d+) ([[:lower:]]) (\d+) \z
       }xms
       or die qq{bad sorting field: '$sort_field'}
       ;
   return pack DECORATOR, @sort_subfields, $i;
   }
 ;;
 sub undecorate {
   my ($decorated, $ar) = @_;
   ;;
   return $ar->[ unpack UNDECORATOR, $decorated ];
   }
 ;;
 my @sorted =
   map undecorate($_, \@matrix),
   sort
   map decorate($_, \@matrix),
   shuffle
   0 .. $#matrix
   ;
 ;;
 my $expected = [
   ['A1a1',  'img1', 'x123', 'y123'],
   ['A1a2',  'img2', 'x123', 'y456'],
   ['A1a12', 'img3', 'x456', 'y789'],
   ['A2a1',  'img9', 'x999', 'y999'],
   ['A10a1', 'img4', 'x456', 'y123'],
   ['A12a1', 'img5', 'x456', 'y456'],
   ['A21a1', 'img8', 'x888', 'y888'],
   ['B2a1',  'img7', 'x777', 'y777'],
   ];
 is_deeply \@sorted, $expected, 'sorted ok',
 ;;
 done_testing;
"
ok 1 - sorted ok
1..1
ok 2 - no warnings
1..2