#!/usr/bin/env perl -l

use strict;
use warnings;
use autodie;

for (@ARGV) {
    my ($input_file, $output_file) = ($_, $_ . '__OUTPUT.txt');
    my (%reformat, @order);

    read_input($input_file, \%reformat, \@order);
    write_output($output_file, \%reformat, \@order);
}

{
    my $re; INIT { $re = qr{^(H\d+,\d+,)(.*)$} }

    sub read_input {
        my ($input_file, $reformat, $order) = @_;

        open my $in_fh, '<', $input_file;

        while (<$in_fh>) {
            next if $. == 1;
            chomp;
            /$re/;
            my ($key, $str_part) = ($1, $2);
            push @$order, $key unless exists $reformat->{$key};
            push @{ $reformat->{$key} }, $str_part;
        }

        return;
    }
}

sub write_output {
    my ($output_file, $reformat, $order) = @_;

    open my $out_fh, '>', $output_file;

    print $out_fh $_, join ' ', @{ $reformat->{$_} } for @$order;

    return;
}

##</code><code>##

$ pm_1168253_reformat_input_WITH_FILES_PRODUCTON.pl pm_1168253_reformat_input_INPUT.txt pm_1168253_reformat_input_INPUT_CLONE.txt; cat pm_1168253_reformat_input_INPUT.txt__OUTPUT.txt; cat pm_1168253_reformat_input_INPUT_CLONE.txt__OUTPUT.txt
H123456,20151209,THIS IS A TEST TO COMBINE ALL MY MATCHING LINES INTO THE FIRST LINE THAT MATCHES.
H654321,20151209,MATCH LINES FOR THIS ACCT INTO THE TOP LINE OF THE ACCT
H432165,20151209,SINGLE LINE FOR THIS ONE
H123456,20151209,THIS IS A TEST TO COMBINE ALL MY MATCHING LINES INTO THE FIRST LINE THAT MATCHES.
H654321,20151209,MATCH LINES FOR THIS ACCT INTO THE TOP LINE OF THE ACCT
H432165,20151209,SINGLE LINE FOR THIS ONE

##</code><code>##

push @$order, $key unless exists $reformat->{$key};