#!/usr/bin/perl --
package Moose::Meta::Method::Accessor::Native::Array::apply;

our $VERSION = '2.1806';

use strict;
use warnings;

use Params::Util ();

use Moose::Role;

with 'Moose::Meta::Method::Accessor::Native::Array::Writer';

sub _maximum_arguments { 1 }

sub _inline_check_arguments {
    my $self = shift;

    return (
        'if (@_ && !Params::Util::_CODELIKE($_[0])) {',
            $self->_inline_throw_exception( InvalidArgumentToMethod =>
                                            'argument                => $_[0],'.
                                            'method_name             => "apply",'.
                                            'type_of_argument        => "code reference",'.
                                            'type                    => "CodeRef",',
            ) . ';',
        '}',
    );
}

sub _adds_members { 0 }

sub _potential_value {
    my $self = shift;
    my ($slot_access) = @_;

    return '[ $_[0] '
             . '? map { $_[0]->($_) } @{ (' . $slot_access . ') } '
             . ':  @{ (' . $slot_access . ') } ]';
}

sub _return_value { '' }

no Moose::Role;

1;


package My;
use Moose;

has list => ( is      => 'rw',
              isa     => 'ArrayRef[Str]',
              traits  => [qw[ Array ]],
              handles => {
                  add_to_list   => 'push',
                  list_elements => 'elements',
                  map_list      => 'map',
                  apply_to_list => 'apply',
              },
);


package main;
my $obj = My->new;
$obj->add_to_list(qw( a b c ));
$obj->apply_to_list(sub { uc });
print "$_\n" for $obj->list_elements;


__END__
A
B
C