package Perl::Critic::Policy::Variables::ProhibitFatCommaInDeclaration;
use warnings;
use strict;
use base 'Perl::Critic::Policy';
use Perl::Critic::Utils ':severities';
use List::Util 'first';

our $VERSION = '0.001';
sub supported_parameters { return }
sub default_severity { return $SEVERITY_HIGH }
sub default_themes { return qw/core bugs/ }
sub applies_to { return 'PPI::Statement::Variable' }

sub violates {
    my ($self, $elem) = @_;
    my $found = first { $_->isa('PPI::Token::Operator') } $elem->children;
    if ($found && $found->content eq '=>') {
		return $self->violation('Fat comma used in declaration',
			'You probably meant "=" instead of "=>"', $found);
    }
    return;
}

1;

##</code><code>##

$ cat testpolicy.pl
#!/usr/bin/env perl
use warnings;
use strict;

my $foo => 'bar';
our $foo => 1;
our $foo => { a=>'blah', b=>'blah' };
our $foo = { a=>'blah', b=>'blah' };
my %foo = ( a=>1, b=>2 );

$ PERL5LIB=/tmp/testlib perlcritic -4 testpolicy.pl
Fat comma used in declaration at line 5, column 9.  You probably meant "=" instead of "=>".  (Severity: 4)
Fat comma used in declaration at line 6, column 10.  You probably meant "=" instead of "=>".  (Severity: 4)
Fat comma used in declaration at line 7, column 10.  You probably meant "=" instead of "=>".  (Severity: 4)