use warnings;
use strict;
use Data::Dump;

local $/ = "\n\n\n";
while (<DATA>) {
	# clobber the header
	s/ ^ \s* Dumpdata\s+example \s* \n \s* -+ \s* \n //msx
		or next;
	my %row;
	$row{$+{key}} = $+{val}
		while m{
			(?: # the very first key doesn't need colon
				  \A \s* (?<key> \w+   )
				# but the other keys need colons
				| ^  \s* (?<key> \w+ : )
			) \s+
			# values should end at the next key
			(?<val> (?: (?!^\s*\w+:) . )+ )
		}xmsg;
	s/\s+/ /g for values %row;
	dd \%row;
}

__DATA__

Dumpdata example
-----------------

Warning bad news here 
    Detail:              Some really nice infos these are 
    Info:              This is a problem
                       but there is a solution


Dumpdata example
-----------------
Warning test
    Detail: foo
            bar
    Info:   quz
            baz
    Spec:   blah

##</code><code>##

{
  "Detail:" => "Some really nice infos these are ",
  "Info:"   => "This is a problem but there is a solution ",
  "Warning" => "bad news here ",
}
{
  "Detail:" => "foo bar ",
  "Info:"   => "quz baz ",
  "Spec:"   => "blah ",
  "Warning" => "test ",
}

##</code><code>##

	my %row = m{
			(?| \A \s* ( \w+   )
			  | ^  \s* ( \w+ : ) ) \s+
			( (?: (?!^\s*\w+:) . )+ )
		}xmsg;