#!/usr/bin/env perl
use warnings;
use strict;
use feature 'say';
use Test::More;

my $re = qr{ \A  ## Reference Implementation ##
		(?<prefix> .* )
		(?<single> (??{ length $+{prefix}
			? '[^'.quotemeta($+{prefix}).']' : '.' }) )
		(?<suffix> (?: (?! \g{single} ) . )* )
	\z }msx;

my $re_nope = qr{ \A  ## one of my early failed attempts
		# the prefix contains only characters that repeat later on
		(?<prefix> (?: (?<rep> . ) (?= .* \g{rep} ) )*  )
		# the single character obviously can't be part of the prefix
		(?<single> (?! \g{rep} ) . )
		# the suffix must not contain the "single" character
		(?<suffix> (?: (?! \g{single} ) . )* )
	\z }msx;

# run the regex against the test cases
for my $len (1..7) {
	my $odo = deduped_odo( map ['a'..chr(ord('a')+$_-1)], 1..$len );
	while (my @c = $odo->()) {
		my $str = join '', @c;
		my $expect = do { my %h; $h{$_}++ for @c;
			my %r = reverse %h; exists $r{1} };
		is $str=~$re, $expect, $str.($expect?' =~':' !~').' re'
		# or, for regexes that match strings with no single chars:
		#is $str!~$re2, $expect, $str.($expect?' !~':' =~').' re2'
			or diag explain
				[ \%-, map [ $-[$_], eval "\$$_", $+[$_] ], 1..@+ ];
	}
}

done_testing;
say "FAIL: $_->{name}"  # a shorter summary of failures
	for grep { !$_->{ok} } Test::More->builder->details;
exit;

# test case generation stuff follows

sub odometer {  # http://www.perlmonks.org/?node_id=1197785
	my @w = map { [ 1, ref eq 'ARRAY' ? @$_ : $_ ] } @_;
	my $done;
	return sub {
		if ($done) { $done=0; return }
		my @cur = map {$$_[$$_[0]]} @w;
		for (my $i=$#w; $i>=0; $i--) {
			last if ++$w[$i][0]<@{$w[$i]};
			$w[$i][0]=1;
			$done=1 unless $i;
		}
		return wantarray ? @cur : join '', @cur;
	}
}

sub deduped_odo {
	my $odo = odometer(@_);
	# this sequence can probably be generated directly...
	my %seen;
	return sub {
		while (1) {
			my @next = $odo->() or return;
			my $pat = do { my ($i,%h)=('A');
				join '', map {$h{$_}//=$i++} @next };
			if ( not $seen{$pat}++ )
				{ return wantarray ? @next : join '', @next }
		}
	}
}