#!/usr/bin/perl

# https://perlmonks.org/?node_id=1224600

use strict;
use warnings;
use Data::Dump 'dd';

my $data = <<'END';
interface XYZ
  given param1 -> child of "interface XYZ"
  given param2 -> child of "interface XYZ"
    given param2.1 -> child of "given param2"
      given param2.1.1 -> child of "given param2.1"
      given param2.1.2 -> child of "given param2.1"
    given param2.2 -> child of "given param2"
  given param3 -> child of "interface XYZ"
  given param4 -> child of "interface XYZ"
interface SECOND
  given param5 -> child of "interface SECOND"
END

my $struct = buildstruct($data);
dd $struct;

sub buildstruct
  {
  my $block = shift;
  my @answers;
  while( $block =~ /^( *)(.*)\n((?:\1 +.*\n)*)/gm )
    {
    my ($head, $rest) = ($2, $3);
    $head =~ s/ ->.*//;
    push @answers, $rest ? { $head => buildstruct($rest) } : $head;
    }
  \@answers;
  }

##</code><code>##

[
  {
    "interface XYZ" => [
      "given param1",
      {
        "given param2" => [
          { "given param2.1" => ["given param2.1.1", "given param2.1.2"] },
          "given param2.2",
        ],
      },
      "given param3",
      "given param4",
    ],
  },
  { "interface SECOND" => ["given param5"] },
]