my $limit = 100;
my $file  = 'big.file';

sub tail {
    my $lim = $limit;

    my @alpha;
    my @beta;
    my $current = \@alpha;

    open( IN, $file ) or die "Cannot open $file for input: $!\n";
    while( <IN> ) {
        push @$current, $_;
        if( scalar @$current > $limit ) {
            if( $current == \@alpha ) {
                @beta = ();
                $current = \@beta;
            }
            else {
                @alpha = ();
                $current = \@alpha;
            }
        }
    }
    close IN;

    return @{$current == \@alpha ? \@beta : \@alpha}[-($limit - scalar @$current)..-1],
        @$current;
}

##</code><code>##

% perl tailbm -30 10 100.lines 

Benchmark: running f_rb_obj, f_rb_obj_u, f_rb_tie, f_rb_tie_u, file_tail, grinder, lastn, lastn_getc, each for at least 30 CPU seconds...
  f_rb_obj:  75 wallclock secs (28.61 usr +  2.71 sys = 31.32 CPU) @ 807.15/s (n=25280)
f_rb_obj_u:  70 wallclock secs (28.59 usr +  2.75 sys = 31.34 CPU) @ 806.32/s (n=25270)
  f_rb_tie:  70 wallclock secs (29.45 usr +  2.37 sys = 31.82 CPU) @ 719.96/s (n=22909)
f_rb_tie_u:  74 wallclock secs (29.05 usr +  2.44 sys = 31.49 CPU) @ 729.76/s (n=22980)
 file_tail: 112 wallclock secs (29.71 usr +  2.34 sys = 32.05 CPU) @ 274.26/s (n=8790)
   grinder:  74 wallclock secs (28.38 usr +  2.77 sys = 31.15 CPU) @ 566.52/s (n=17647)
     lastn:  69 wallclock secs (19.78 usr + 11.34 sys = 31.12 CPU) @ 22.88/s (n=712)
lastn_getc:  77 wallclock secs (18.88 usr + 13.17 sys = 32.05 CPU) @ 19.78/s (n=634)

##</code><code>##

% perl tailbm -30 100 721994.lines 
Benchmark: running f_rb_obj, f_rb_obj_u, f_rb_tie, f_rb_tie_u, file_tail, grinder, each for at least 30 CPU seconds...
  f_rb_obj:  54 wallclock secs (30.52 usr +  0.93 sys = 31.45 CPU) @ 147.31/s (n=4633)
f_rb_obj_u:  70 wallclock secs (30.24 usr +  0.83 sys = 31.07 CPU) @ 144.19/s (n=4480)
  f_rb_tie:  69 wallclock secs (30.70 usr +  0.60 sys = 31.30 CPU) @ 121.31/s (n=3797)
f_rb_tie_u:  68 wallclock secs (29.96 usr +  0.53 sys = 30.49 CPU) @ 118.99/s (n=3628)
 file_tail:  76 wallclock secs (31.02 usr +  0.83 sys = 31.85 CPU) @ 60.60/s (n=1930)
   grinder: 121 wallclock secs (33.17 usr +  2.10 sys = 35.27 CPU) @  0.09/s (n=3)
            (warning: too few iterations for a reliable count)
     lastn:  40 wallclock secs (20.15 usr + 10.80 sys = 30.95 CPU) @ 19.48/s (n=603)
lastn_getc:  42 wallclock secs (18.05 usr + 13.81 sys = 31.86 CPU) @ 17.70/s (n=564)

##</code><code>##

#! /usr/bin/perl -w

use strict;
use Benchmark;
use File::ReadBackwards;
use File::Tail;

use constant VERIFY => 0;
my $count = shift or die "Benchmark count not specified, try 1000 (iters) or -10 (CPU secs).\n";
my $limit = shift or die "Number of lines not specified, try 100.\n";
my $file  = shift or die "No filename specified on command-line.\n";
my @result;

sub f_rb_obj {
	my $lim = $limit;
	my $bw = File::ReadBackwards->new( $file ) or die "can't read $file: $!\n" ;

	my $line;
	my @lines;
	while( defined( my $line = $bw->readline ) ) {
    	push @lines, $line;
		last if --$lim <= 0;
	}
	reverse @lines;
}

sub f_rb_tie {
	my $lim = $limit;
	tie *BW, 'File::ReadBackwards', $file or die "can't read $file: $!\n" ;

	my @lines;
	while( <BW> ) {
    	push @lines, $_;
		last if --$lim <= 0;
	}
	reverse @lines;
}

sub f_rb_obj_u {
	my $lim = $limit;
	my $bw = File::ReadBackwards->new( $file ) or die "can't read $file: $!\n" ;

	my $line;
	my @lines;
	while( defined( my $line = $bw->readline ) ) {
    	unshift @lines, $line;
		last if --$lim <= 0;
	}
	@lines;
}

sub f_rb_tie_u {
	my $lim = $limit;
	tie *BW, 'File::ReadBackwards', $file or die "can't read $file: $!\n" ;

	my @lines;
	while( <BW> ) {
    	unshift @lines, $_;
		last if --$lim <= 0;
	}
	@lines;
}

sub grinder {
	my $lim = $limit;

	my @alpha;
	my @beta;
	my $current = \@alpha;

	open( IN, $file ) or die "Cannot open $file for input: $!\n";
	while( <IN> ) {
		push @$current, $_;
		if( scalar @$current > $limit ) {
			if( $current == \@alpha ) {
				@beta = ();
				$current = \@beta;
			}
			else {
				@alpha = ();
				$current = \@alpha;
			}
		}	
	}
	close IN;

	return @{$current == \@alpha ? \@beta : \@alpha}[-($limit - scalar @$current)..-1],
		@$current;
}

sub lastn {
	my $lines = $limit;
    my $fh;
    if (! open($fh, $file) ) {
        print "Can't open $file: $!";
        return;
    }
    binmode($fh);
    sysseek($fh, 0, 2);  # Seek to end
    my $nlcount=0;
    while($nlcount<$lines) {
        last unless sysseek($fh, -1, 1);
        sysread($fh, $_, 1, 0) || die;
        $nlcount++ if ( $_ eq "\n");
        last if $nlcount==$lines;
        last unless (sysseek($fh, -1, 1));
    }
    seek($fh, sysseek($fh, 0, 1), 0) || warn;
    my @lines = <$fh>;
	close $fh;
	@lines;
}

sub lastn_getc {
	my $lines = $limit;
    my $fh;
    if (! open($fh, $file) ) {
        print "Can't open $file: $!";
        return;

    }
    binmode($fh);
    seek($fh, 0, 2);  # Seek to end
    my $nlcount=0;
    while($nlcount<$lines) {
        last unless seek($fh, -1, 1);
        $_=getc($fh);
        die unless defined $_;
        $nlcount++ if ( $_ eq "\n");
        last if $nlcount==$lines;
        last unless (seek($fh, -1, 1));
    }
    my @lines = <$fh>;
	close $fh;
	@lines;
}

sub file_tail {
	my $fh = File::Tail->new(name=>$file,tail=>$limit);
	if( !defined $fh ) {
		die "Could not create File::Tail object on $file: $!\n";
	}
	$fh->nowait(1);
	my @lines;
	local $" = "";
	while( defined( my $line = $fh->read() )) {
		last unless $line;
		push @lines, $line;
	}
	# $fh->close;
	@lines;
}

if( VERIFY ) {
	local $" = "";
	for my $test( qw/f_rb_obj f_rb_tie grinder lastn lastn_getc file_tail/ ) {
		warn "$test\n", eval( "$test()" ), "\n";
	}
	exit;
}

timethese( $count, {
	'f_rb_obj'   => \&f_rb_obj, 
	'f_rb_tie'   => \&f_rb_tie, 
	'f_rb_obj_u' => \&f_rb_obj_u, 
	'f_rb_tie_u' => \&f_rb_tie_u, 
	'grinder'    => \&grinder, 
	'file_tail'  => \&file_tail, 
	'lastn'      => \&lastn, 
	'lastn_getc' => \&lastn_getc, 
});
__END__