#!/usr/bin/perl -w

use strict;
use Benchmark qw(cmpthese);

my $varshort = "abc:12345 def:54321 ghi:13245";
my $varlong  = "$varshort " x 120;

# subs
sub regex {
  my $str = shift;
  my @arr = ($str =~ /(.{3}):/g);
}

sub substring {
  my $str = shift;
  my @arr;
  my $p = 0;
  push(@arr,substr( $str, ($p=index($str, ':', $p+1 ))-3,3)) while $p > -1;
  pop(@arr);
  return @arr;
}

sub sexeger {
  my $str = reverse shift;
  my @arr = reverse 
            map {$_ = reverse $_} 
            ($str =~ /:(.{3})/g);
}

sub regexpShort  { regex($varshort) }
sub regexpLong   { regex($varlong)  }
sub sexegeShort  { sexeger($varshort) }
sub sexegeLong   { sexeger($varlong)  }
sub substrShort  { substring($varshort) }
sub substrLong   { substring($varlong) }

# unit tests
my $rs = "@{[regexpShort()]}";
my $rl = "@{[regexpLong()]}";
my $ss = "@{[sexegeShort()]}";
my $sl = "@{[sexegeLong()]}";
my $bs = "@{[substrShort()]}";
my $bl = "@{[substrLong()]}";

die unless $rs eq $ss;
die unless $rs eq $bs;
die unless $rl eq $sl;
die unless $rl eq $bl;

# benchmark
cmpthese(-3,
	 {
           regexpShort  => \&regexpShort,
           substrShort  => \&substrShort,
           sexegeShort  => \&sexegeShort,
	 }
	);

cmpthese(-3,
	 {
           regexpLong   => \&regexpLong,
           substrLong   => \&substrLong,
           sexegeLong   => \&sexegeLong,
	 }
	);