#!/opt/perl/bin/perl -w
use strict;
use warnings;
use HTML::TokeParser::Simple;
use IO::File;


my ( $htmlInfile, $htmlOutfile, $cssOutfile ) = @ARGV;

$htmlOutfile ||= 'out.html';
$cssOutfile ||= 'out.css' ;

my $htmlFile	= new IO::File "> $htmlOutfile" or die "Can't open $htmlOutfile for writing: $!\n";
my $cssFile	= new IO::File "> $cssOutfile"  or die "Can't open $cssOutfile for writing: $!\n";



my $parser	= HTML::TokeParser::Simple->new($htmlInfile);

my %styles;
while (my $token = $parser->get_token) {

	# link in our new css file
	if ($token->is_end_tag('/head') ){
		$htmlFile->print( "<link rel='stylesheet' type='text/css' href='$cssOutfile'>\n" );
	}

	# find and remove inline style definitions 
	if ($token->is_start_tag) {
		my $tag		= $token->return_tag;
		my $attr		= $token->return_attr;
		
		# If we have an inline style attribute get the value
		# then delete it from the tag
		if ( defined $attr->{style} ){
			$styles{ $attr->{style} }{$tag} += 1;
			$token->delete_attr('style');
		}
	}

   
	$htmlFile->print( $token->as_is ); 
}


# print our collected styles into the css file
while (my ( $style, $tags ) = each %styles ){
	#li, p { font-family: Times; font-size: 10pt }
	$cssFile->print( join( ', ', sort keys( %$tags ) ) . " { $style }\n");
}