#!perl

use strict;
use warnings;

my @tstrs = qw(
abdc
aBcxz
abccCcccz
abcdefghijklmnop
qrstuvwxyzabz
zabc
abca
);

sub m_sorted {
    $_[0] !~ /(.)(??{"[^lc($1)-z]"})/;
}

sub substr_sorted {
    my $lstr = lc shift;
    my $test = substr($lstr, 0, 1);
    for my $i (1..length($lstr)-1) {
        my $ntst = substr($lstr, $i, 1);
        return 0 if  $ntst lt $test;
        $test = $ntst;
    }
    1;
}

sub expl_sorted {
    my $lstr = lc shift;
    $lstr eq join('', sort split //, $lstr);
}

my $gen_m_pat = join '', map "$_*", 'a'..'z';
sub gen_m_sorted {
    $_[0] =~ /^$gen_m_pat$/oi;
}

use Benchmark;
timethese(100_000, {
#    'm_sorted'      => sub { for (@tstrs) { chomp; my $is = m_sorted $_; } },
    'substr_sorted' => sub { for (@tstrs) { chomp; my $is = substr_sorted $_; }},
    'expl_sorted'   => sub { for (@tstrs) { chomp; my $is = expl_sorted $_; }},
    'gen_m'   => sub { for (@tstrs) { chomp; my $is = gen_m_sorted $_; }},
});

for (@tstrs) {
    print "$_\n";
    print " m says: ", m_sorted($_) ? '' : 'not ', "sorted\n";
    print " substr says: ", substr_sorted($_) ? '' : 'not ', "sorted\n";
    print " expl says: ", expl_sorted($_) ? '' : 'not ', "sorted\n";
    print " gen_m says: ", gen_m_sorted($_) ? '' : 'not ', "sorted\n";
}