setpath.pl [ENV_VAR] [:NEWPATH | NEWPATH: | -[-]OLDPATH]

  Default ENV_VAR is PATH
  :NEWPATH appends ":NEWPATH" at end of ENV_VAR
  NEWPATH: prepends "NEWPATH:" at start of ENV_VAR
  -OLDPATH deletes first instance of "OLDPATH" from ENV_VAR
  --OLDPATH deletes all instances of "OLDPATH" from ENV_VAR

##</code><code>##

 setpath.pl VAR1 :NEWPATH VAR2 OTHERPATH: VAR3 --BADPATH
#
# shell function would be:
function setpath { /full/path/to/setpath.pl $*; if ... };

##</code><code>##

#!/usr/bin/perl

use strict;

my $Usage = <<ENDUSE;
Usage:  $0 [ENV_VAR] [:NEWPATH | NEWPATH: | -[-]OLDPATH] ...

  default ENV_VAR is PATH
  :NEWPATH  add NEWPATH at end of ENV_VAR
   NEWPATH: add NEWPATH at start of ENV_VAR
  -OLDPATH  delete first instance of OLDPATH from ENV_VAR
  --OLDPATH delete all instances of OLDPATH from ENV_VAR

You may add/remove multiple path strings from a single ENV_VAR,
and you may change multiple ENV_VARs with one command, e.g.:

 $0  VAR1 /new/path:  VAR2 --/bad/path :/good/path 

ENDUSE

my %env_change;
my $varname = 'PATH';
my $pathrgx = qr{(?:\.{0,2}/)+\.?\w.+};

for ( @ARGV ) {
    my $edit_op =
         ( m{ ^:$pathrgx$ }x ) ? 'append' :
         ( m{ ^$pathrgx:$ }x ) ? 'prepend' : 
         ( m{ ^-($pathrgx)$ }x ) ? 'rm1st' : 
         ( m{ ^--($pathrgx)$ }x ) ? 'rmall' : '';

    if ( substr( $edit_op, 0, 2 ) eq 'rm' ) {
        push @{$env_change{$varname}{$edit_op}}, $1;
    }
    elsif ( $edit_op ) {
        $env_change{$varname}{$edit_op} .= $_;
    }
    elsif ( /^\w+$/ ) {
        $varname = $_;
    }
    else {
        warn "$_ is not a valid ENV variable or path string\n";
        die $Usage;
    }
}

my $home  = $ENV{HOME} || $ENV{LOGDIR} || (getpwuid($<))[7];
my $fName = "$home/.setpath.out";
if ( -e $fName ) {
    unlink ( $fName )
        or die( "Unable to unlink previous $fName file ($!)\n" );
}
open( OUT, "> $fName" );

for $varname ( keys %env_change ) {
    my $varval = '';
    if ( ! length( $ENV{$varname} )) {
        $varval = $env_change{$varname}{prepend} .
                  $env_change{$varname}{append};

        if ( $varval eq '' ) {
            warn "No additions to non-existent $varname; skipping that...\n";
            next;
        }
    }
    else {
        if ( exists( $env_change{$varname}{rmall} )) {
            $ENV{$varname} =~ s/$_//g for ( @{$env_change{$varname}{rmall}} );
        }
        if ( exists( $env_change{$varname}{rm1st} )) {
            $ENV{$varname} =~ s/$_// for ( @{$env_change{$varname}{rm1st}} );
        }
        $varval = join( ':',
                       $env_change{$varname}{prepend},
                       split( /:+/, $ENV{$varname} ),
                       $env_change{$varname}{append} );
    }
    $varval =~ s/^://;
    $varval =~ s/:$//;
    $varval =~ s/:{2,}/:/g;

    print OUT "export $varname=$varval\n";
}
exit(0);