P:\test>499358-2
460 : [ alabama sangrita radiator amalgam rutabaga camellia lasagna mascagni tacomayo marzipan ]
472 : [ alabama sangrita radiator amalgam rutabaga azalia lasagna mascagni tacomayo marzipan ]
474 : [ alabama sangrita radiator amalgam rutabaga azalia lasagna mascagni tacomayo taiglach ]
Elapsed: 0.015 seconds.

##</code><code>##

#! perl -slw
use strict;
use Time::HiRes qw[ time ];

my $start = time;

my @lookup = map{ ($_+1) * $_ /2 } 0 .. 80;
sub calcScore {
    my( %chars, $score );
    $chars{ $_ }++ for map{ split'' } @{ $_[0] };
    $score += $lookup[ $_ ] for values %chars;
    return $score;
}

my @cats = map{ [ split ' ' ] } <DATA>;
close DATA;

## Sort the words in each category by their individual scores (descending)
my %wordScores;
@{ $cats[ $_ ] } = sort{
    ( $wordScores{ $b } ||= calcScore [$b] )
    <=>
    ( $wordScores{ $a } ||= calcScore [$a] )
} @{ $cats[ $_ ] } for 0 .. $#cats;

## form our guess from the highest scoring words in each category
my @guess = map{ $cats[ $_ ][ 0 ] } 0 .. $#cats;
my $best = calcScore \@guess;

## Loop over the categories swaping the other words in that cateory 
## for the guessed word. If we get a better score, start again.
LOOP:
for my $iCat ( 0 .. $#cats ) {
    my $cat = $cats[ $iCat ];
    for my $iWord ( 1 .. $#$cat ) {
        my $test = calcScore [ 
            @guess[ 0 .. $iCat -1 ], 
            $cat->[ $iWord ], 
            @guess[ $iCat+1 .. $#guess ] 
        ];
        if( $test > $best ) {
            $best = $test;
            $guess[ $iCat ] = $cat->[ $iWord ];
            print "$best : [ @guess ]";
            redo LOOP;
        }
    }
}
printf "Elapsed: %.3f seconds.\n", time - $start;

__DATA__
alabama arkansas alaska delaware hawaii indiana kansas montana delaware
sazerac sangrita
radiator gastank engine heater fender wheel detent battery clutch mirror window
alloy amalgam vanadium copper steel
rutabaga limabean cress carrot sorrel squash cabbage pepper lettuce beet leek celery endive rhubarb parsnip pumpkin
azalia camellia dahlia gardenia gentian vervain canna hepatica bluebell anemone oleander
lasagna macaroni pastina gnocchi tortelli alfabeto
mascagni britten menotti
unamas tacotime pizzahut tacobell panago tacomayo edojapan hardees
caramel marzipan taiglach taffy brittle fondant toffee dragee