use strict;
use warnings;
use Data::Dumper;

my %default_values = ( 'float' => 0,
                       'int' => 3, # Unique value for visibility during testing
                       'bool' => 'false'
                       );
my %structs;

parse_struct_definitions();
print Dumper(%structs);

sub parse_struct_definitions {
    # Reads the typedef struct lines in the __DATA__ section to populate the
    # %structs hash.  Created for simple updates to the defined structures
    # (simply copy and paste from the header files into the DATA section
    # below)

    local $/ = 'typedef struct {';
    while (my $line = <DATA>) {
        chomp $line;
        next if $line !~ /\w/;
        
        # For me to parse out the data more easily:
        $line =~ s/\n/ /g;
        $line =~ s/\s+/ /g;

        # Break the line into members and the struct name
        my ($member_string, $name) = $line =~ /([^\}]+)\s*\}\s*(.+)/;
        my @members = split ';', $member_string;
        $name =~ tr/; //d;

        foreach my $member (@members) {
            next if $member !~ /\w/;
            my ($type, $member_name) = split " ", $member;

            push @{$structs{$name}}, [ $type, $member_name, $default_values{$type} ];
        }
    }
} # end of parse_struct_definitions

__DATA__
typedef struct {
    float one;
    float two;
    int   three;
    bool  potato;
} struct_name;

typedef struct {
    float one; /* 0.0 */
    float two; /* 0.0 */
    int   three; /* 0 */
    bool  potato; /* false */
} struct_name_with_comments;