### INCLUDES #########################################################################################
use strict;
use Bio::SeqIO;
use Carp;

### PARAMETERS #######################################################################################
my $chr_file = $ARGV[0];
my $seq_file = $ARGV[1];

if ( 2 != scalar(@ARGV) ) {
        croak 'Invalid parameter number';
        }
elsif ( ! -e $chr_file || ! -T $chr_file ) {
        croak 'Missing or invalid chromsome-listing file';
        }
elsif ( ! -e $seq_file || ! -T $seq_file ) {
        croak 'Missing or invalid sequence-listing file';
        }

### LOCALS ###########################################################################################
my @chromosomes;
my %motifs;

### LOAD THE CHROMOSOME LIST #########################################################################
open(my $fh_chr, '<', $chr_file) or croak "Unable to open chromsome list: $chr_file";

while (<$fh_chr>) {

        s/^\s+//;
        s/\s+$//;

        my $row = $_;
        next() if (!$row);

        push @chromosomes, $row;

        }

close($fh_chr);

### LOAD THE MOTIF LIST ##############################################################################
open(my $fh_seq, '<', $seq_file) or croak "Unable to open motif file: $seq_file";

while (<$fh_seq>) {

        s/^\s+//;
        s/\s+$//;

        my @row = split("\t");

        next() if ( 2 != scalar(@row) );

        $motifs{ $row[0] } = $row[1];

        }

close($fh_seq);

### FIND SEQUENCE MOTIFS #############################################################################
foreach my $chromosome (@chromosomes) {

        my $directory = $chromosome.'/';
        my $file = 'chr'.$chromosome.'.fa.masked';
        my $path = $directory.$file;

        my $seqio = Bio::SeqIO->new(
                -file    =>  "<$path",
                -format  =>  'largefasta'
                );

        my $seq = $seqio->next_seq();
        my $sequence = $seq->seq();

        foreach my $motif ( keys(%motifs) ) {

                my $str = $motifs{$motif};
                my $len = length($str);
                my $pos = 0;

                while ( ($pos = index($sequence, $str, $pos)) >= 0 ) {
                        print join("\t", $chromosome, $pos, $motif), "\n";
                        $pos += $len;
                        }

                }

        }