#! perl -slw
use strict;
use List::Util qw[ first ];
use constant {
    XLIMITS => [ -1e308, 1.0, 2.5, 3.6, 4.8, 5.0, 6.123456789, 1e308 ],
    YLIMITS => [ -1e308, 1.0, 3.3, 4.6, 5.7, 6.8, 7.912345678, 1e308 ],
    XYMAP   => [
        [ 1, 2, 3, 4, 5, 6, 7 ],
        [ 2, 3, 4, 5, 6, 7, 8 ],
        [ 3, 4, 5, 6, 7, 8, 9 ],
        [ 4, 5, 6, 7, 8, 9, 0 ],
        [ 5, 6, 7, 8, 9, 0, 1 ],
        [ 6, 7, 8, 9, 0, 1, 2 ],
        [ 7, 8, 9, 0, 1, 2, 3 ],
    ],
};

sub lookup{
    my( $xVal, $yVal ) = @_;
    my $xIndex = -1 + first{ XLIMITS->[ $_ ] > $xVal } 0 .. $#{ XLIMITS() };
    my $yIndex = -1 + first{ YLIMITS->[ $_ ] > $yVal } 0 .. $#{ YLIMITS() };
    return XYMAP->[ $yIndex ][ $xIndex ];
}


printf '         ' . '%-7.5g   ' x @{ YLIMITS() } . "\n", @{ XLIMITS() };
printf "%7.5g\n\t" . '        %2d' x $#{ XLIMITS() } . "\n",
    YLIMITS->[ $_ ], @{ XYMAP->[ $_ ] }
    for 0 .. $#{ YLIMITS() } - 1;
printf "%7.5g\n", YLIMITS->[ -1 ];
printf "\nEnter X:Y : ";

while( <STDIN> ) {
    chomp;
    if( my( $x, $y ) = m[([\d.]+):([\d.]+)] ) {
        printf "[$x:$y] => %d\n", lookup( $x, $y );
    }
    else {
       warn 'Bad input. Try again';
    }
    printf "\nEnter X:Y : ";
}

__END__
C:\test>575245
         -1e+308   1         2.5       3.6       4.8       5         6.1235    1e+308
-1e+308
                 1         2         3         4         5         6         7
      1
                 2         3         4         5         6         7         8
    3.3
                 3         4         5         6         7         8         9
    4.6
                 4         5         6         7         8         9         0
    5.7
                 5         6         7         8         9         0         1
    6.8
                 6         7         8         9         0         1         2
 7.9123
                 7         8         9         0         1         2         3
 1e+308

Enter X:Y : 0:0
[0:0] => 1

Enter X:Y : 999:999
[999:999] => 3

Enter X:Y : 2:2
[2:2] => 3