sub html_calendar {
  my ($month, $year, $eventshashref) = @_;
  my $dt = DateTime->new(year  => $year,
                         month => $month,
                         day   => 1,
                        );
  my $calendar = qq[
   <table class="calendarmonth"><thead>
  <tr><th colspan="7" class="monthname">] . $dt->month_name . qq[ $year</th></tr>
  <tr><th>Sun</th><th>Mon</th><th>Tue</th><th>Wed</th><th>Thu</th><th>Fri</th><th>Sat</th></tr>
</thead><tbody>
  <tr>];
  $calendar .= '<td class="othermonth">&nbsp;</td>' for 1 .. ($dt->dow % 7);
  while ($dt->month == $month) {
    $calendar .= qq[<td><span class="daynum">] . $dt->mday . '</span>';
    if (ref $eventshashref and exists $$eventshashref{$dt->mday}) {
      my $class   = $$eventshashref{$dt->mday()}{class};
      my $time    = $$eventshashref{$dt->mday()}{time};
      my $desc    = $$eventshashref{$dt->mday()}{shortdesc};
      my $tooltip = $$eventshashref{$dt->mday()}{longdesc};
      $calendar .= qq[<div class="calendarevent $class"><span class="eventtime">$time</span>
                     <abbr title="$tooltip">$desc</abbr></div>];
    }
    $calendar .= qq[</td>];
    $dt = $dt->add(days => 1);
    if ($dt->dow == 7) {
      $calendar .= "</tr>\n  <tr>",
    }
  }
  $calendar .= qq[</tr>\n</tbody></table>];
  return $calendar;
}

##</code><code>##

my $cal = html_calendar(11, 2006, { 23 => {class => 'holiday', time => '', shortdesc => 'Thanksgiving', longdesc => 'Stay home and stuff yourself.'}});