# Example usages:
#   server_admin -u USER -p PASSWD -s SERVER add_server name=NAME ipaddr=IPADDR
#   server_admin -u USER -p PASSWD -s SERVER add_app type=TYPE name=NAME
#   server_admin -u USER -p PASSWD -s SERVER add_user name=NAME passwd=PASSWD

use strict;
use warnings;

use Getopt::Long   qw( );
use File::Basename qw( basename );


my ($USERNAME, $PASSWORD, $SERVER);


sub usage {
   my $prog = basename($0);
   print STDERR @_;
   print STDERR "usage: $prog ...\n";
   print STDERR "       $prog -h for more details\n";
   exit(1);
}


sub help {
   my $prog = basename($0);
   print @_;
   # ...[ Provide detailed help to STDOUT. ]...
   exit(0);
}


sub get_args {
   my (@arg_names) = @_;

   my %args = map { split(/=/, $_, 2 } @ARGV;

   foreach (@arg_names) {
      if (not $args{$_}) {
         usage("Missing arg $_.\n");
      }
   }

   my @rv = delete @args{@arg_names};

   foreach (keys %args) {
      usage("Unknown arg $_. Accepting " . join(', ', @arg_names) . "\n");
   }

   return @rv;
}


sub add_server {
   my ($name, $ipaddr) = get_args(qw( name ipaddr ));
   ...
}


sub add_app {
   my ($type, $name) = get_args(qw( type name ));
   ...
}


sub add_user {
   my ($name, $passwd) = get_args(qw( name passwd ));
   ...
}


{
   my %action = (
      add_server => \&add_server,
      add_app    => \&add_app,
      add_user   => \&add_user,
   );

   Getopt::Long::Configure(qw( posix_default ));
   Getopt::Long::GetOptions(
      'help|h|?'   => \&help,
      'user|u=s'   => \$USERNAME,
      'passwd|p=s' => \$PASSWORD,
      'server|s=s' => \$SERVER,
   )
      or usage();

   my $action = shift(@ARGV);

   usage() unless defined $USERNAME
           and    defined $PASSWORD
           and    defined $SERVER
           and    defined $action;

   my $action = $actions{$action}
      or usage("Unknown action $action\n");

   $action->();
}